1

使用以下代码

{-# LANGUAGE Arrows #-}
{-# LANGUAGE NoMonomorphismRestriction #-}
import Text.XML.HXT.Core

parseXml :: IOSArrow XmlTree XmlTree
parseXml = getChildren >>> getChildren >>>
  proc x -> do
    y <- x >- hasName "item"
    returnA -< x

main :: IO ()
main = do
    person <- runX (readString [withValidate no]
                    "<xml><item>John</item><item2>Smith</item2></xml>"
                    >>> parseXml)
    putStrLn $ show person
    return ()

我得到输出

[NTree (XTag "item" []) [NTree (XText "John") []]]

所以它似乎hasName "item"适用于x我没想到的。使用箭头我得到parseXml：

parseXml
   = getChildren >>> getChildren >>>
      (arr (\ x -> (x, x)) >>>
         (first (hasName "item") >>> arr (\ (y, x) -> x)))

所以我有箭头图

                                                       y
                                   /-- hasName "item" ---
                               x  /                       
-- getChildren -- getChildren ---\x->(x,x)              \(y,x)->x --- final result
                                  \                       / 
                                   \---------------------/

为什么hasName "item"也适用于元组的第二位？我认为 haskell 中没有状态并hasName "item" x返回一个新对象而不是更改x.

相关问题：从箭头符号中分解箭头是否是有效的转换？

我原来的问题

我有以下代码：

{-# LANGUAGE Arrows #-}
import Text.XML.HXT.Core

data Person = Person { forname :: String, surname :: String } deriving (Show)

parseXml :: IOSArrow XmlTree Person
parseXml = proc x -> do
    forname <- x >- this /> this /> hasName "fn" /> getText
    surname <- x >- this /> this /> hasName "sn" /> getText
    returnA -< Person forname surname

main :: IO ()
main = do
    person <- runX (readString [withValidate no]
                               "<p><fn>John</fn><sn>Smith</sn></p>"
                    >>> parseXml)
    putStrLn $ show person
    return ()

如果我运行它一切正常，我得到输出

[Person {forname = "John", surname = "Smith"}]

但是如果我改变parseXml以避免this陈述

parseXml :: IOSArrow XmlTree Person
parseXml = (getChildren >>> getChildren) >>> proc x -> do
    forname <- x >- hasName "fn" /> getText
    surname <- x >- hasName "sn" /> getText
    returnA -< Person forname surname

再也无法解析任何人（输出为[]）。调查问题

parseXml :: IOSArrow XmlTree Person
parseXml = (getChildren >>> getChildren) >>>
  proc x -> do
    forname <- x >- withTraceLevel 5 traceTree >>> hasName "fn" /> getText
    surname <- x >- hasName "sn" /> getText
    returnA -< Person forname surname

我得到了输出

content of: 
============

---XTag "fn"
   |
   +---XText "John"



content of: 
============

---XTag "sn"
   |
   +---XText "Smith"


[]

所以一切看起来都很好，但是有代码

parseXml :: IOSArrow XmlTree Person
parseXml = (getChildren >>> getChildren) >>>
  proc x -> do
    forname <- x >- hasName "fn" /> getText
    surname <- x >- withTraceLevel 5 traceTree >>> hasName "sn" /> getText
    returnA -< Person forname surname

我有

content of: 
============

---XTag "fn"
   |
   +---XText "John"


[]

所以在我看来，输入的值x在两个语句之间发生了变化。看起来是在附加到箭头之前hasName "fn"应用的。但是两条线之间不应该保持不变吗？xsurnamex

4

2 回答 2

2

不，输入不能改变，它也不会。

您在行中编写的内容

proc x -> do
  y <- x >- hasName "item"
  returnA -< x

只是一个过滤器删除所有未命名的节点item。他的相当于箭头

hasName "item" `guards` this

你可以用

{-# LANGUAGE Arrows #-}
{-# LANGUAGE NoMonomorphismRestriction #-}

module Main where

import Text.XML.HXT.Core

parseXml0 :: IOSArrow XmlTree XmlTree
parseXml0 = getChildren >>> getChildren >>>
  proc x -> do
    _ <- hasName "item" -< x
    returnA -< x

parseXml1 :: IOSArrow XmlTree XmlTree
parseXml1 = getChildren >>> getChildren >>>
            (hasName "item" `guards` this)

main1 :: Show c => IOSArrow XmlTree c -> IO ()
main1 parseXml = do
    person <- runX (readString [withValidate no]
                    "<xml><item>John</item><item2>Smith</item2></xml>"
                    >>> parseXml)
    putStrLn $ show person
    return ()

main :: IO ()
main = main1 parseXml0 >> main1 parseXml1
于 2014-03-28T12:20:01.643 回答
1

编辑：好的，现在你已经完全改变了你的问题！

工作示例应解释如下：

对于顶级标签x

  • 遍历名称为( getText) 的孙子 ( ) 的所有文本 ( )，用于保存这些值this /> this"fn"hasName "fn"forname
  • 遍历名称为( getText) 的孙子 ( ) 的所有文本 ( )，用于保存这些值this /> this"sn"hasName "sn"surname
  • Person forname surname每对这样的产量

这看起来很有效，但可能没有做你认为它正在做的事情。例如，尝试在输入上运行代码"<p><fn>John</fn><sn>Smith</sn><fn>Anne</fn><sn>Jones</sn></p>"。打印了四个名字。

损坏的示例应解释如下：

对于每一个孙子x

  • 如果x有名称"fn"，则将文本存储在其中forname（否则跳到下一个x）
  • 如果x有名称"sn"，则将文本存储在其中surname（否则跳到下一个x）

一个标签不能有名字"fn" 和名字"sn"！因此，每个标签都被跳过。

您的调查只是显示了跳过标签的计算点。在第一种情况下，两个标签都存在，因为尚未过滤任何内容。在第二种情况下，仅存在"fn"标签，因为第一个命令已过滤掉其他所有内容。

编辑：您可能会发现此示例（根据列表单子完成）具有指导意义。

import Control.Monad ((>=>))

data XML = Text String | Tag String [XML] deriving Show

this :: a -> [a]
this = return

(/>) :: (a -> [XML]) -> (XML -> [c]) -> a -> [c]
f /> g = f >=> getChildren >=> g

(>--) :: a -> (a -> b) -> b
x >-- f = f x

getChildren :: XML -> [XML]
getChildren (Text _) = []
getChildren (Tag _ c) = c

hasName :: String -> XML -> [XML]
hasName _ (Text _) = []
hasName n i@(Tag n' _) = if n == n' then [i] else []

getText :: XML -> [String]
getText (Text t) = [t]
getText (Tag _ _) = []

parseXML :: XML -> [(String, String)]
parseXML = \x -> do
  forname <- x >-- (this /> this /> hasName "fn" /> getText)
  surname <- x >-- (this /> this /> hasName "sn" /> getText)
  return (forname, surname)

parseXMLBroken :: XML -> [(String, String)]
parseXMLBroken = getChildren >=> getChildren >=> \x -> do
  forname <- x >-- (hasName "fn" /> getText)
  surname <- x >-- (hasName "sn" /> getText)
  return (forname, surname)

runX :: (XML -> a) -> XML -> a
runX f xml = f (Tag "/" [xml])

xml :: XML
xml = (Tag "p" [ Tag "fn" [Text "John"]
               , Tag "sn" [Text "Smith"] ])

example1 = runX parseXML xml

example2 = runX parseXMLBroken xml

*Main> example1
[("John","Smith")]
*Main> example2
[]
于 2014-03-28T10:18:16.303 回答