11

我有两个代码片段试图将浮点列表转换为 Vector3 或 Vector2 列表。这个想法是一次从列表中取出 2/3 个元素并将它们组合为一个向量。最终结果是一系列向量。

    let rec vec3Seq floatList =
        seq {
            match floatList with
            | x::y::z::tail -> yield Vector3(x,y,z)
                               yield! vec3Seq tail
            | [] -> ()
            | _ -> failwith "float array not multiple of 3?"
            }

    let rec vec2Seq floatList =
        seq {
            match floatList with
            | x::y::tail -> yield Vector2(x,y)
                            yield! vec2Seq tail
            | [] -> ()
            | _ -> failwith "float array not multiple of 2?"
            }

代码看起来非常相似，但似乎没有办法提取公共部分。有任何想法吗？

4

4 回答 4

13

这是一种方法。我不确定这到底有多简单，但它确实抽象了一些重复的逻辑。

let rec mkSeq (|P|_|) x =
  seq {
    match x with
    | P(p,tail) -> 
        yield p
        yield! mkSeq (|P|_|) tail
    | [] -> ()
    | _ -> failwith "List length mismatch" }

let vec3Seq =
  mkSeq (function
  | x::y::z::tail -> Some(Vector3(x,y,z), tail)
  | _ -> None)
于 2010-02-14T02:53:22.373 回答
2

正如 Rex 评论的那样，如果您只希望在两种情况下这样做，那么如果您保留代码原样，您可能不会遇到任何问题。但是，如果您想提取一个通用模式，那么您可以编写一个函数，将列表拆分为指定长度（2 或 3 或任何其他数字）的子列表。完成此操作后，您只会使用map将指定长度的每个列表转换为Vector.

F# 库中没有拆分列表的功能（据我所知），因此您必须自己实现它。大致可以这样完成：

let divideList n list = 
  // 'acc' - accumulates the resulting sub-lists (reversed order)
  // 'tmp' - stores values of the current sub-list (reversed order)
  // 'c'   - the length of 'tmp' so far
  // 'list' - the remaining elements to process
  let rec divideListAux acc tmp c list = 
    match list with
    | x::xs when c = n - 1 -> 
      // we're adding last element to 'tmp', 
      // so we reverse it and add it to accumulator
      divideListAux ((List.rev (x::tmp))::acc) [] 0 xs
    | x::xs ->
      // add one more value to 'tmp'
      divideListAux acc (x::tmp) (c+1) xs
    | [] when c = 0 ->  List.rev acc // no more elements and empty 'tmp'
    | _ -> failwithf "not multiple of %d" n // non-empty 'tmp'
  divideListAux [] [] 0 list

现在，您可以使用此函数来实现您的两个转换，如下所示：

seq { for [x; y] in floatList |> divideList 2 -> Vector2(x,y) }
seq { for [x; y; z] in floatList |> divideList 3 -> Vector3(x,y,z) }

这将给出一个警告，因为我们使用了一个不完整的模式，它期望返回的列表的长度分别为 2 或 3，但这是正确的期望，所以代码可以正常工作。我还使用了一个简短版本的序列表达式，->它的作用与 相同do yield，但它只能用于像这样的简单情况。

于 2010-02-14T02:51:11.810 回答
2

这与 kvb 的解决方案类似，但不使用部分活动模式。

let rec listToSeq convert (list:list<_>) =
    seq {
        if not(List.isEmpty list) then
            let list, vec = convert list
            yield vec
            yield! listToSeq convert list
        }

let vec2Seq = listToSeq (function
    | x::y::tail -> tail, Vector2(x,y)
    | _ -> failwith "float array not multiple of 2?")

let vec3Seq = listToSeq (function
    | x::y::z::tail -> tail, Vector3(x,y,z)
    | _ -> failwith "float array not multiple of 3?")
于 2010-02-14T05:31:31.247 回答
0

老实说，你所拥有的几乎是它所能得到的，尽管你可以使用这个来变得更紧凑：

// take 3 [1 .. 5] returns ([1; 2; 3], [4; 5])
let rec take count l =
    match count, l with
    | 0, xs -> [], xs
    | n, x::xs -> let res, xs' = take (count - 1) xs in x::res, xs'
    | n, [] -> failwith "Index out of range"

// split 3 [1 .. 6] returns [[1;2;3]; [4;5;6]]
let rec split count l =
    seq { match take count l with
          | xs, ys -> yield xs; if ys <> [] then yield! split count ys }

let vec3Seq l = split 3 l |> Seq.map (fun [x;y;z] -> Vector3(x, y, z))
let vec2Seq l = split 2 l |> Seq.map (fun [x;y] -> Vector2(x, y))

现在，分解列表的过程被转移到它自己的通用“take”和“split”函数中，更容易将它映射到您想要的类型。

于 2010-02-14T03:05:24.467 回答