1

我使用类创建了一个 ALV 树视图CL_SALV_TREE。

一切正常，但我想在节点展开时抓住事件，以填充自动调整树列大小的函数。

我的问题是，扩展事件是HANDLE_EXPAND_NC类的私有方法，CL_GUI_ALV_TREE我实际上不知道如何捕获这个事件。我愿意接受任何想法，并感谢您的时间。

4

2 回答 2

1

据我所知，只有在展开尚未包含子项的文件夹时才会通知您（_NC方法/事件名称的一部分表示这一点）。这是为了延迟加载树。SAP 菜单或 IMG 中显示的树就是一个很好的例子 - 当您展开顶级节点时，您实际上可以看到正在加载的部分树。

如果这对您来说足够了，请使用由实现EXPAND_EMPTY_FOLDER的接口的事件。不过，似乎没有一个好的演示程序。IF_SALV_EVENTS_TREECL_SALV_EVENTS_TREE

于 2014-03-20T07:58:18.000 回答
0

这是一个最小的可重现示例，它显示EXPAND_EMPTY_FOLDER当您展开最初没有子节点的节点时触发事件，在该事件期间添加子节点：

CLASS lcl_app DEFINITION.
  PUBLIC SECTION.
    METHODS pbo
      RAISING
        cx_salv_error.
  PRIVATE SECTION.
    DATA: salv   TYPE REF TO cl_salv_tree,
          scarrs TYPE STANDARD TABLE OF scarr.
    METHODS on_expand_empty_folder
      FOR EVENT expand_empty_folder
                  OF cl_salv_events_tree
      IMPORTING node_key.
ENDCLASS.

CLASS lcl_app IMPLEMENTATION.
  METHOD pbo.
    IF salv IS NOT BOUND.
      cl_salv_tree=>factory( EXPORTING r_container = cl_gui_container=>screen0
                             IMPORTING r_salv_tree = salv
                             CHANGING  t_table     = scarrs ).
      DATA(lo_settings) = salv->get_tree_settings( ).
      lo_settings->set_hierarchy_size( 30 ).
      DATA(event) = salv->get_event( ).
      salv->get_functions( )->add_function( name = 'NEW' text = 'NEW' tooltip = '' position = 1 ).
      SET HANDLER on_expand_empty_folder FOR event.
      SELECT * FROM scarr INTO TABLE @DATA(local_scarrs).
      LOOP AT local_scarrs REFERENCE INTO DATA(scarr).
        salv->get_nodes( )->add_node(
          related_node = space " (root node)
          relationship = cl_gui_column_tree=>relat_last_child
          text         = |{ scarr->carrid } - { scarr->carrname }|
          data_row     = scarr->*
          folder       = abap_true
          expander     = abap_true ).
      ENDLOOP.
      salv->display( ).
    ENDIF.
    LOOP AT SCREEN.
      screen-active = '0'.
      MODIFY SCREEN.
    ENDLOOP.
  ENDMETHOD.
  METHOD on_expand_empty_folder.
    TRY.
        DATA(scarr) = CAST scarr( salv->get_nodes( )->get_node( node_key )->get_data_row( ) )->*.
        salv->get_nodes( )->add_node(
          related_node = node_key
          relationship = cl_gui_column_tree=>relat_last_child
          text         = |Node added at time of expand below { scarr-carrid }| ).
      CATCH cx_root INTO DATA(lx).
        MESSAGE lx TYPE 'I' DISPLAY LIKE 'E'.
        LEAVE PROGRAM.
    ENDTRY.
  ENDMETHOD.
ENDCLASS.

PARAMETERS dummy.

LOAD-OF-PROGRAM.
  DATA(app) = NEW lcl_app( ).

AT SELECTION-SCREEN OUTPUT.
  TRY.
      app->pbo( ).
    CATCH cx_root INTO DATA(lx).
      MESSAGE lx TYPE 'S' DISPLAY LIKE 'E'.
  ENDTRY.
于 2019-11-10T14:31:17.237 回答