1

我正在尝试从串行线 RS232 上的主机读取一个简单的字符串。两者的接收 - 传输参数相同：

Baudrate: 9600;
Data: 8bit;
Parity: None;
Stop: 1bit;
Flow Control: None;

我试图发送这个字符串：

!A243B324C213D300#

我用 '！' 和'#'作为标题并完成以确保字符串将被完全接收。问题是我可以在第 15 个字符 (3) 之前接收到字符串。

我知道这一点，因为如果我使用此代码：

procedure TForm1.ComPort1RxChar(Sender: TObject; Count: Integer);
begin
 ComPort1.ReadStr(Str, Count);
 memo1.Lines.Add(str);
end;

我再看看吧

!A243B324C213D3

00#

我试图扩展 comport 的缓冲区，但没有结果。

那么为什么我不能一次收到完整的字符串呢？

我在这里找到了这个库，直到现在它都可以正常工作：

http://sourceforge.net/projects/comport/

4

2 回答 2

4

TComPort 组件附带了另一个组件：TComDataPacket。只需将其连接到 TComPort，设置 StartString 和 StopString 属性并使用事件 onPacket 即可获取完整数据。

例子：

...
    ComDataPacket1.Comport := Comport1;
    ComDataPacket1.StartString := '!';
    ComDataPacket1.StopString := '#';
    ComDataPacket1.onPacket := ComDataPacket1Packet;
...

//this is real code from one of my applications where I use it for barcode reader service
procedure TDM.ComDataPacket1Packet(Sender: TObject; const Str: string);
begin
     BarCodeReader.Barcode := Str;  
end;
于 2014-03-16T15:42:56.430 回答
3

您不能依赖在这种低级别的通信中接收完整的消息。此外，您不能依赖一次只接收一条消息。

你必须实现一些东西，这将保证只通知完整的消息。

为此，您必须存储传入的数据，直到收到完整的消息（标题和完成标志）。

这是一个带有TMessageBuffer类的小型控制台应用程序，它处理传入的数据和完整的消息

program so_22436319;

{$APPTYPE CONSOLE}
{$R *.res}

uses
  SysUtils;

type
  TMessageBuffer = class
  private
    FBuffer : string;
    FMsgPart : Boolean;
    procedure DoHandleMessage( const CompleteMessage : string );
  public
    procedure AddData( const Data : string );
  end;

procedure Test;
var
  LMsgBuffer : TMessageBuffer;
begin
  LMsgBuffer := TMessageBuffer.Create;
  try
    // receive complete message
    LMsgBuffer.AddData( '!A243B324C213D300#' );
    // receive 2 complete message in one go
    LMsgBuffer.AddData( '!A243B324C213D300#!A243B324C213D300#' );
    // receive parts of the message
    LMsgBuffer.AddData( '!A243B324' );
    LMsgBuffer.AddData( 'C213D300#!A243' );
    LMsgBuffer.AddData( 'B324C213D300#!A' );
    LMsgBuffer.AddData( '243B324C2' );
    LMsgBuffer.AddData( '13D300#' );

  finally
    LMsgBuffer.Free;
  end;
end;

  { TMessageBuffer }

procedure TMessageBuffer.AddData( const Data : string );
var
  LIdx : Integer;
  LChar : Char;
begin
  for LIdx := 1 to Length( Data ) do
  begin
    LChar := Data[LIdx];
    if FMsgPart then
      if LChar = '#' then
      begin
        DoHandleMessage( FBuffer );
        FMsgPart := False;
        FBuffer := '';
      end
      else
      begin
        FBuffer := FBuffer + LChar
      end
    else if LChar = '!' then
    begin
      FMsgPart := True;
    end;
  end;
end;

procedure TMessageBuffer.DoHandleMessage( const CompleteMessage : string );
begin
  Writeln( 'MSG: ', CompleteMessage );
end;

begin
  try
    Test;
  except
    on E : Exception do
      Writeln( E.ClassName, ': ', E.Message );
  end;
  ReadLn;
end.

生成的输出是

味精：A243B324C213D300
味精：A243B324C213D300
味精：A243B324C213D300
味精：A243B324C213D300
味精：A243B324C213D300
味精：A243B324C213D300

该类删除了标头和完成字符，因为这是传输协议的一部分，因此不再需要。但是，如果您愿意，仍然可以添加它。

于 2014-03-16T13:49:56.837 回答