2

下面的两个例子都可以吗，还是第二个例子不好？

案例1：留在顶层目录，使用catdir访问子目录

#!/usr/bin/env perl
use warnings; use strict;

my $dir = 'my_dir_with_subdir';
my ( $count, $dh );

use File::Spec::Functions;
$count = 0;

opendir $dh, $dir or die $!;
while ( defined( my $file = readdir $dh ) ) {
    next if $file =~ /^\.{1,2}$/;
    my $sub_dir = catdir $dir, $file;
    if ( -d $sub_dir ) {
        opendir my $dh, $sub_dir or die $!;
        while ( defined( my $file = readdir $dh ) ) {
            next if $file =~ /^\.{1,2}$/;
            $count++;
        }
        closedir $dh or die $!;
    }
    else {
        $count++;
    }
}

closedir $dh or die $!;
print "$count\n";

案例2：退出前切换到子目录并恢复顶层目录

use Cwd;
my $old = cwd;
$count = 0;
opendir $dh, $dir or die $!;
chdir $dir or die $!;
while ( defined( my $file = readdir $dh ) ) {
    next if $file =~ /^\.{1,2}$/;
    if ( -d $file ) {
        opendir my $dh, $file or die $!;
        chdir $file or die $!;
        while ( defined( my $file = readdir $dh ) ) {
            next if $file =~ /^\.{1,2}$/;
            $count++;
        }
        closedir $dh or die $!;
        chdir $dir;
    }
    else {
        $count++;
    }
}
closedir $dh or die $!;
chdir $old or die $!;
print "$count\n";
4

3 回答 3

2

您的问题是您应该更改到您正在经历的目录还是留在顶级目录中。

答案是：视情况而定。

例如，考虑File::Find。默认行为是确实更改目录。但是，该模块还提供了一个no_chdir选项以防万一。

对于您的示例，File::Find可能不合适，因为您不想递归所有子目录，而只想递归一个。这是一个基于File::Slurp::read_dir的脚本变体。

#!/usr/bin/perl

use strict; use warnings;

use File::Slurp;
use File::Spec::Functions qw( catfile );

my ($dir) = @ARGV;

my $contents = read_dir $dir;
my $count = 0;

for my $entry ( @$contents ) {
    my $path = catfile $dir, $entry;
    -f $path and ++ $count and next;
    -d _ and $count += () = read_dir $path;
}

print "$count\n";
于 2010-02-11T11:22:25.503 回答
1

对于您的示例，最好更改为子目录，并且不要在最后更改回原始目录。那是因为每个进程都有自己的“当前目录”，所以你的 perl 脚本正在改变它自己的当前目录这一事实并不意味着 shell 的当前目录被改变了；保持不变。

如果这是更大脚本的一部分，那就不同了；我的一般偏好是不更改目录，只是为了减少脚本中任何时候当前目录的混淆。

于 2010-02-11T12:14:19.073 回答
0

使用 File::Find，就像你已经建议的那样:)

使用模块来解决这样的问题几乎总是比自己动手要好，除非你真的想了解步行目录......

于 2010-02-11T08:45:15.923 回答