3

与 Moose 一起使用时，是否可以让 Log4perl 正确显示日志事件的行号和包/类，而不是始终在第 99 行显示 Method::Delegation？

在我的例子中，我创建了一个属性 isa Log::Log4perl::Logger 并将各种日志记录级别委托给我的类（日志、警告、错误......）。这样做还会将Delegation.pm 显示为文件。

谢谢！

4

2 回答 2

2

您没有提供几乎足够的信息来诊断您的问题（例如，什么是 Method::Delegation 以及它如何连接到 Log4perl），但我的感觉告诉我您可能有一个包装器方法，您可以从中调用 Log4perl 方法。您应该在这个包装器中增加$Log::Log4perl::caller_depthfrom 的值（并在调用 Log4perl 后减少它），以便确定正确的位置。

例如在Moose中，我使用：

package MyApp::Role::Log;

use MooseX::Role::Strict;
use Log::Log4perl;

my @methods = qw(
    log trace debug info warn error fatal
    is_trace is_debug is_info is_warn is_error is_fatal
    logexit logwarn error_warn logdie error_die
    logcarp logcluck logcroak logconfess
);

has '_logger' => (
    is => 'ro',
    isa => 'Log::Log4perl::Logger',
    lazy_build => 1,
    handles => \@methods,
);

around $_ => sub {
    my $orig = shift;
    my $this = shift;

    # one level for this method itself
    # two levels for Class::MOP::Method::Wrapped (the "around" wrapper)
    # one level for Moose::Meta::Method::Delegation (the "handles" wrapper)
    local $Log::Log4perl::caller_depth += 4;

    my $return = $this->$orig(@_);

    $Log::Log4perl::caller_depth -= 4;
    return $return;

} foreach @methods;


sub _build__logger
{
    my $this = shift;

    Log::Log4perl->easy_init() if not Log::Log4perl::initialized();
    return Log::Log4perl->get_logger(ref $this)
}

no MooseX::Role::Strict;
1;

请注意，CPAN 模块MooseX::Log::Log4perl不会增加 caller_depth，它肯定应该这样做。

于 2010-02-09T20:59:26.757 回答
0

是的。根据Log::Log4perl::Layout::PatternLayout你想要的是%F和的组合%L。%L是“发出日志语句的文件中的行号”并且%F是“发生日志事件的文件”。

或者，最简单的方法是使用%l以下方法：

调用方法的完全限定名称后跟调用者源文件名和括号之间的行号。

于 2010-02-10T00:07:46.513 回答