我们在使用新的 1.8 subversion 客户端时遇到了问题（我们使用 TortoiseSVN 1.8.5 和 SlikSVN 1.8.5）。在某些情况下，重新集成后能够继续使用功能分支的新 SVN 1.8 功能似乎不起作用。
当主干包含本地合并信息（文件或子树上的合并信息）时，它不起作用。这可能会导致重新集成后分支重用的问题。如果使用“keep alive dance”（使用仅记录选项）完成分支重用，这对 1.7 客户端来说不是问题。
我制作了一个脚本，从头开始说明这个问题。它可以使用 1.8 客户端针对空存储库运行。
下面的脚本有 10 个步骤。步骤 1-5 用于创建在主干中具有本地合并信息的启动情况。步骤 6-9 模拟在功能分支的生命周期中对主干进行的更改2。第 10 步是失败的步骤，它模拟了重新集成后功能分支重用的第一步。
这是第 10 步中的错误：
svn: E195016: Reintegrate can only be used if revisions 8 through 11 were pre
viously merged from svn://svn2010/practice/branches/featurebranch2 to the reinte
grate source, but this is not the case:
trunk/file1.txt
Missing ranges: /trunk/file1.txt:9
这是（Windows）脚本。
@ECHO OFF
ECHO ------------------------------------------------------------------
ECHO STEP 0: Create a repository
ECHO ------------------------------------------------------------------
if exist repo rmdir repo /S/Q
if exist trunk rmdir trunk /S/Q
if exist featurebranch1 rmdir featurebranch1 /S/Q
if exist featurebranch2 rmdir featurebranch2 /S/Q
svnadmin create repo --compatible-version 1.8
REM Make url based on current directory and replace backslashes by forward slashes
set url="file:///%cd:\=/%/repo"
ECHO url=%url%
ECHO ------------------------------------------------------------------
ECHO STEP 1: Create a trunk with 2 files
ECHO ------------------------------------------------------------------
svn mkdir -m "Create trunk" %url%/trunk
svn checkout %url%/trunk
echo Original file contents created in the trunk. > trunk\file1.txt
echo Original file contents created in the trunk. > trunk\file2.txt
svn add trunk\file1.txt
svn add trunk\file2.txt
svn -m "Added 2 files" commit trunk
ECHO ------------------------------------------------------------------
ECHO STEP 2: Create a copy (feature branch) from the trunk
ECHO ------------------------------------------------------------------
svn mkdir -m "Create branches dir" %url%/branches
svn copy -m "Create featurebranch1" %url%/trunk %url%/branches/featurebranch1
ECHO ------------------------------------------------------------------
ECHO STEP 3: Modify both files in the feature branch
ECHO ------------------------------------------------------------------
svn checkout %url%/branches/featurebranch1
echo Additional file contents created in featurebranch1. >> featurebranch1\file1.txt
echo Additional file contents created in featurebranch1. >> featurebranch1\file2.txt
svn -m "Modified 2 files in featurebranch1" commit featurebranch1
ECHO ------------------------------------------------------------------
ECHO STEP 4: Merge both files from featurebranch1 to the trunk to
ECHO create local mergeinfo on both files
ECHO ------------------------------------------------------------------
svn update trunk
svn merge %url%/branches/featurebranch1/file1.txt trunk/file1.txt
svn merge %url%/branches/featurebranch1/file2.txt trunk/file2.txt
svn -m "Merged 2 files from featurebranch1 to trunk" commit trunk
ECHO ------------------------------------------------------------------
ECHO STEP 5: Delete featurebranch2, we only needed it for the
ECHO initial setup
ECHO ------------------------------------------------------------------
svn delete -m "Delete featurebranch1" %url%/branches/featurebranch1
ECHO ------------------------------------------------------------------
ECHO STEP 6: This is the start of the problematic scenario
ECHO Create a new featurebranch2 from the trunk and a wc for it
ECHO ------------------------------------------------------------------
svn copy -m "Create featurebranch2" %url%/trunk %url%/branches/featurebranch2
svn checkout %url%/branches/featurebranch2
ECHO ------------------------------------------------------------------
ECHO STEP 7: Modify the contents of file1.txt in the trunk and leave
ECHO the contents of file2.txt unchanged (this is important)
ECHO ------------------------------------------------------------------
echo Additional file contents created in the trunk. >> trunk\file1.txt
svn -m "Modified file1.txt in the trunk" commit trunk
ECHO ------------------------------------------------------------------
ECHO STEP 8: Sync merge the trunk to featurebranch2
ECHO ------------------------------------------------------------------
svn update featurebranch2
svn merge %url%/trunk featurebranch2
svn -m "Sync merged the trunk into featurebranch2" commit featurebranch2
ECHO ------------------------------------------------------------------
ECHO STEP 9: Reintegrate featurebranch2 back into the trunk
ECHO ------------------------------------------------------------------
svn update trunk
svn merge %url%/branches/featurebranch2 trunk
svn -m "Reintegrated featurebranch2 back into the trunk" commit trunk
ECHO ------------------------------------------------------------------
ECHO STEP 10: Try to reuse featurebranch2 after it was reintegrated
ECHO Sync merge it from the trunk. THIS FAILS with SVN 1.8
ECHO ------------------------------------------------------------------
svn update featurebranch2
REM on SVN 1.7 we would use --record-only
svn merge %url%/trunk featurebranch2
:EOF
我不明白为什么会这样。此外，错误报告缺少 file1.txt 的范围，而似乎是缺少合并信息的 file2.txt。虽然不是解决方案，但删除主干中 file2.txt 上的本地合并信息似乎也可以解决问题。这也暗示错误消息报告了错误文件的内容。
编辑：对@gbjbaanb 的响应即使错误消息相同，此问题也比您所指的问题更微妙。在我的情况下，失败的不是重新集成到主干，而是分支之后的重用。
另外，如果我查看 file1.txt 和 file2.txt 的合并信息，似乎 file2.txt 缺少 featurebranch2 的合并信息记录，因此问题出在 file2.txt 而不是 file1.txt 的错误提示。因为 file1.txt 在 featurebranch2 的生命周期中在主干中发生了更改，并且 file2.txt 不是关于主干的合并信息，所以在步骤 8 的合并过程中没有在 file2.txt 上设置。我相信这是它开始的地方出轨。这不会影响重新集成到主干，但会阻止功能分支之后的重用。
编辑：回复@David W 我已经尝试过--record-only -c 11这也适用于 Windows 端。我已经在没有-c的情况下尝试过（通常你不应该，我知道，但在这种情况下没有其他更改）然后它报告：
svn: E200004: The required merge is reintegrate-like, and the record-only option
cannot be used with this kind of merge
为了更好地衡量，我还尝试了 --record-only -c 1-11，我期望这与不使用-c相同（因为 11 是 HEAD）。我最初的期望是它会以与不使用相同的方式失败-c，但事实并非如此。它的成功方式与-c 11相同。
但我这篇文章的重点是，使用 SVN 1.8，我们不需要做保持活动的诡计。（草案）文档说：
如果您在将分支重新集成到主干后选择不删除分支，您可以继续从主干执行同步合并，然后再次重新集成分支[37]。如果这样做，则只有在第一次重新集成后对分支所做的更改才会合并到主干。( http://svnbook.red-bean.com )。
从 Subversion 1.8 发行说明：
使用自动重新集成合并可以以任何顺序在两个分支之间来回合并（不再需要“keep-alive dance”）。为获得最佳结果，建议始终合并所有符合条件的修订，即不使用 svn merge 的 -r 或 -c 选项。仅合并符合条件的修订的子集会增加未来合并期间出现问题的可能性。（https://subversion.apache.org/docs/release-notes/1.8.html）
所以我的观点是，这个分支重用没有保持活动的诡计显然在本地合并信息面前不起作用，我的脚本似乎表明了这一点。
如果您仍然认为有关缺失范围的警告可能是正确的，除了可能报告的范围编号，请告诉我我的脚本中导致缺失范围的位置。我的脚本是主干和分支之间的简单来回切换，没有对它们进行并行处理。
您还可以解释为什么还要通过在步骤 7 中添加： “echo Additional file contents created in trunk. >> trunk\file2.txt” 来解释为什么要修改 file2.txt，这将导致在步骤 10 中没有错误。修改附加文件在主干上无法解决缺失范围问题。