2

我正在玩 afBedSheet 并希望处理对目录的所有请求。例如，对 /abcd 的请求调用 abcdMethod#doSomething

我将路线设置为

@Contribute { serviceId="Routes" }
static Void contributeRoutes(OrderedConfig conf) {
  conf.add(Route(`/abcd/?`, abcdMethod#doSomething))
}

然而，当我浏览到 /abcd 我得到 404 错误:(

我该如何进行这项工作？

4

1 回答 1

1

确保您的路由处理程序方法doSomething()不接受任何参数。例如，将以下内容另存为Example.fan：

using afIoc
using afBedSheet

class MyRoutes {
  Text abcdMethod() {
    return Text.fromPlain("Hello from `abcd/`!")
  }
}

class AppModule {
  @Contribute { serviceId="Routes" }
  static Void contributeRoutes(OrderedConfig conf) {
    conf.add(Route(`/abcd/?`, MyRoutes#abcdMethod))
  }
}

class Example {
  Int main() {
    afBedSheet::Main().main([AppModule#.qname, "8080"])
  }
}

并运行它：

> fan Example.fan -env dev

（附加 -env dev将列出 404 页面上的所有可用路由。）

因为/abcd/?有一个尾随?，它将匹配 的文件 URLhttp://localhost:8080/abcd和 的目录 URL http://localhost:8080/abcd/。但请注意，它不会匹配内部的任何 URL /abcd。

要匹配内部/abcd的文件，请将 Uri 参数添加到您的路由方法（以捕获路径）并将您的路由更改为：

/abcd/**  only matches direct descendants --> /abcd/wotever

/abcd/*** will match subdirectories too   --> /abcd/wot/ever

例如：

using afIoc
using afBedSheet

class MyRoutes {
  Text abcdMethod(Uri? subpath) {
    return Text.fromPlain("Hello from `abcd/` - the sub-path is $subpath")
  }
}

class AppModule {
  @Contribute { serviceId="Routes" }
  static Void contributeRoutes(OrderedConfig conf) {
    conf.add(Route(`/abcd/***`, MyRoutes#abcdMethod))
  }
}

class Example {
  Int main() {
    afBedSheet::Main().main([AppModule#.qname, "8080"])
  }
}
于 2014-02-21T08:31:52.773 回答