1

所以基本上我正在处理 Win32 上的伪 asm 代码，并且我试图让它重新组装。

在代码中，我看到这样的数据结构：

errtable    errentry <1, 16h>
            errentry <2, 2>
            errentry <3, 2>
            errentry <4, 18h>
            errentry <5, 0Dh>
            .....

在 .text 部分，我看到如下代码：

cmp     eax, dword ptr errtable.oscode[ecx*8]
mov     eax, errtable.errnocode[ecx*8]

基本上像上面那样的 asm 代码/数据不能直接在 windows 32 位上由 NASM/MASM 重新组装。所以我必须调整这个代码/数据......

我在网上搜索，找到了C中数据结构的定义：

struct errentry {
    unsigned long oscode;           /* OS return value */
    int errnocode;  /* System V error code */
};

static struct errentry errtable[] = {
    {  ERROR_INVALID_FUNCTION,       EINVAL    },  /* 1 */
    {  ERROR_FILE_NOT_FOUND,         ENOENT    },  /* 2 */
    {  ERROR_PATH_NOT_FOUND,         ENOENT    },  /* 3 */
    {  ERROR_TOO_MANY_OPEN_FILES,    EMFILE    },  /* 4 */
    {  ERROR_ACCESS_DENIED,          EACCES    },  /* 5 */
    {  ERROR_INVALID_HANDLE,         EBADF     },  /* 6 */
    {  ERROR_ARENA_TRASHED,          ENOMEM    },  /* 7 */
    {  ERROR_NOT_ENOUGH_MEMORY,      ENOMEM    },  /* 8 */
    .........

所以我的问题是：如何修改 asm 代码/数据以使其重新组装？

谢谢！

4

1 回答 1

1

您同时标记了和，您需要哪个？我确信这可以通过某种宏在 NASM 中完成，但在 MASM 中它是轻而易举的。

ENOENT      equ 2
EBADF       equ 9
ENOMEM      equ 12
EACCES      equ 13
EINVAL      equ 22
EMFILE      equ 24

errentry struc
    oscode      dd  ?
    ernocode    dd  ?
errentry ends

.data
errtable    errentry    <ERROR_INVALID_FUNCTION, EINVAL>, \
                        <ERROR_FILE_NOT_FOUND, ENOENT>, \
                        <ERROR_PATH_NOT_FOUND, ENOENT>, \
                        <ERROR_TOO_MANY_OPEN_FILES, EMFILE>, \
                        <ERROR_ACCESS_DENIED, EACCES>, \
                        <ERROR_INVALID_HANDLE, EBADF>, \
                        <ERROR_ARENA_TRASHED, ENOMEM>, \
                        <ERROR_NOT_ENOUGH_MEMORY, ENOMEM>
                        ; ...
.code
start:

NextCode:
    cmp     eax, errtable.oscode[ecx * 8]
    jne     NotFound

    mov     eax, errtable.ernocode[ecx * 8]
    jmp     Next

NotFound:
    ; Err number not found, return something

Next:

还有一些测试代码：
我们将改变寄存器，所以我们不需要保存它们printf

include masm32rt.inc

ENOENT      equ 2
EBADF       equ 9
ENOMEM      equ 12
EACCES      equ 13
EINVAL      equ 22
EMFILE      equ 24

errentry struc
    oscode      dd  ?
    ernocode    dd  ?
errentry ends

.data
fmtint      db  "OS Code = %d, Err Code = %d", 13, 10, 0
fmtstr      db  "OS Code %d NOT FOUND!!!", 13, 10, 0

errtable    errentry    <ERROR_INVALID_FUNCTION, EINVAL>, \
                        <ERROR_FILE_NOT_FOUND, ENOENT>, \
                        <ERROR_PATH_NOT_FOUND, ENOENT>, \
                        <ERROR_TOO_MANY_OPEN_FILES, EMFILE>, \
                        <ERROR_ACCESS_DENIED, EACCES>, \
                        <ERROR_INVALID_HANDLE, EBADF>, \
                        <ERROR_ARENA_TRASHED, ENOMEM>, \
                        <ERROR_NOT_ENOUGH_MEMORY, ENOMEM>
                        ; ...
errtable_len    equ ($ - errtable) / 8

.code
start:

    mov     edi, 1
    xor     ebx, ebx
NextCode:
    cmp     edi, errtable.oscode[ebx * 8]
    jne     NotFound

    invoke  crt_printf, offset fmtint, errtable.oscode[ebx * 8], errtable.ernocode[ebx * 8]
    jmp     Next

NotFound:
    ; Err number not found, return something 
    invoke  crt_printf, offset fmtstr, edi 


Next:
    inc     ebx
    inc     edi
    cmp     edi, 12 ; loop 3 more than our test array
    jne     NextCode

    inkey
    invoke  ExitProcess, 0
end start

在此处输入图像描述

于 2014-02-20T00:32:24.493 回答