9

我需要从我的域类中调用静态资源插件 ( http://www.grails.org/Static+Resources+Plugin )。

这在控制器中完美运行：

 def tstLink = resourceLinkTo(dir:"docs/${identifier}",file:originalFileName)

但在域类中我得到

Exception Message: No signature of method: static org.maflt.ibidem.Item.resourceLinkTo() is applicable for argument types: (java.util.LinkedHashMap) values: [[dir:docs/19e9ea9d-5fae-4a35-80a2-daedfbc7c2c2, file:2009-11-12_1552.png]]

我认为这是一个普遍的问题。

那么如何在域类中将 taglib 称为函数呢？

4

2 回答 2

11

不久前，我在开发一个应用程序时遇到了这个问题。我最终做的是在服务方法中调用标签：

class MyService {
   def grailsApplication //autowired by spring

   def methodThatUsesATag(identifier, originalFileName) {
      //This is the default grails tag library
      def g = grailsApplication.mainContext.getBean('org.codehaus.groovy.grails.plugins.web.taglib.ApplicationTagLib')

      g.resourceLinkTo(dir:"docs/${identifier}",file:originalFileName)
   }
}

然后在我的域类中，我也可以通过 spring 自动装配来访问该服务：

class MyDomain {
    String originalFileName
    def myService  //autowired

    static transients = ['myService'] //Necessary so that GORM doesn't try to persist the service instance.

    //You can create a method at this point that uses your
    //service to return what you need from the domain instance.
    def myMethod() {
       myService.methodThatUsesATag(id, originalFileName)
    }
}
于 2010-01-29T14:22:11.683 回答
-1

大多数标签库依赖于来自控制器的数据，因此通常无法重用它们，而其他标签库则关注视图逻辑，因此您通常不想将其放入域类中。

也就是说，我相信你有你的理由，所以也许 taglib 的来源会有所帮助：

class ResourceTagLib  {

    def externalResourceServerService

    def resourceLinkTo = { attrs ->
        out << externalResourceServerService.uri
        out << '/'
        if(attrs['dir']) {
            out << "${attrs['dir']}/"
        }
        if(attrs['file']) {
            out << "${attrs['file']}"
        }
    }
}

即将externalResourceServerService 注入到您的域类中，其余的应该很简单。

于 2010-01-29T10:36:02.353 回答