1

这从XML 扩展到使用 XSL 的 XML 问题 我设法导入 exslt 并根据给出的解决方案（感谢 Kyle Butt）修改了我的代码，如下所示：

<xsl:stylesheet version="1.0"
              xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
              xmlns:func="http://exslt.org/functions"
              xmlns:set="http://exslt.org/sets"
              extension-element-prefixes="set">

<xsl:import href="set.distinct.function.xsl"/>

<xsl:output method="xml" indent="yes"/>

<xsl:template match="gallery">
  <gallery>
    <xsl:variable name="gallery" select="."/>
    <xsl:for-each select="set:distinct(photo/tag/event)">
      <xsl:value-of select="."/>
      <event name="{.}">
        <xsl:variable name="event" select="." />
        <xsl:for-each select="set:distinct($gallery/object/tag[event=.]/group)">
          <group name="{.}">
            <xsl:variable name="group" select="." />
            <xsl:apply-templates select="$gallery/object[tag/event=$event][tag/group=$group]" />
          </group>
        </xsl:for-each>
      </event>
    </xsl:for-each>
  </gallery>
</xsl:template>

但是输出中有错误说 - '函数集：distinct（）失败。值不能为空。如何解决这个问题？

顺便说一句 XML 输入：

<gallery>
  <photo>
    <tag>
      <event>Birthday</event>
      <group>Family</group>
      <other>Swensens</other>
    </tag>
  </photo>
  <photo>..</photo>
</gallery>

& 所需的 XML 输出：

<gallery>
  <event name="Birthday">
    <group name="Family">
      <photo>
        <tag>
         <other>Swensens</other>
        </tag>
      </photo>
      <photo>..</photo>
    </group>
    <group>..</group>
  </event>
  <event>..</event>
</gallery>
4

1 回答 1

0

当我按原样在您的输入上运行您的 XSL 时，我没有收到错误，但这是我得到的输出：

<gallery>
  Birthday
  <event name="Birthday"/>
</gallery>

因此，这里发生的许多事情并没有让您获得您想要的输出。一件事是您只是将事件的名称输出为画廊节点的值，因此要摆脱它，您需要删除 <xsl:value-of select="." /> 在第一个 xsl:for-each 中（可能是这个调试代码留在里面了吗？）

然后在事件中查看 xsl:for-each 中的这一部分：

<xsl:variable name="event" select="." />
<xsl:for-each select="set:distinct($gallery/object/tag[event=.]/group)">

我看到 set:distinct 中的 XPath 存在一些问题：

  1. 您提供的 XML 输入中画廊节点下方的节点是 <photo>，在您的 XPath 中您有“对象”。
  2. 您没有使用 $event 变量来检查事件节点——标签上的谓词应该是 [event=$event]。

这些是导致您看到的错误的原因——XPath 没有选择任何内容，因此您在 null 上调用 set:distinct。

因此，进行这些更正后，我得到的输出是：

<gallery>
  <event name="Birthday">
    <group name="Family"/>
  </event>
</gallery>

然后 <xsl:apply-templates select="$gallery/object[tag/event=$event][tag/group=$group]" /> 中的 XPath 也需要将对象更改为照片。在我的样式表中，我添加了一个与照片匹配的模板，因为它没有包含在您的示例样式表中，所以我的样式表现在看起来像：

<xsl:stylesheet version="1.0"
          xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
          xmlns:func="http://exslt.org/functions"
          xmlns:set="http://exslt.org/sets"
          extension-element-prefixes="set">
<xsl:output method="xml" indent="yes"/>

<xsl:template match="gallery">
  <gallery>
    <xsl:variable name="gallery" select="."/>
    <xsl:for-each select="set:distinct(photo/tag/event)">
      <event name="{.}">
        <xsl:variable name="event" select="." />
        <xsl:for-each select="set:distinct($gallery/photo/tag[event=$event]/group)">
          <group name="{.}">
            <xsl:variable name="group" select="." />
            <xsl:apply-templates select="$gallery/photo[tag/event=$event][tag/group=$group]" />
          </group>
        </xsl:for-each>
      </event>
    </xsl:for-each>
  </gallery>
</xsl:template>

<xsl:template match="photo">
  <photo>
    <tag>
      <xsl:copy-of select="tag/*[not(name(.)='group') and not(name(.)='event')]" />
    </tag>
  </photo>
</xsl:template>
</xsl:stylesheet>

我得到的输出是：

<gallery>
  <event name="Birthday">
    <group name="Family">
      <photo>
        <tag>
          <other>Swensens</other>
        </tag>
      </photo>
    </group>
  </event>
</gallery>

多田！！

于 2010-01-31T20:14:19.650 回答