audio - 如何使用处理来反转音频波

Question

有没有办法分析应用程序记录的音频并反转它的波形？例如，在模拟音频中，声波就像 0,1,-1 的正弦波。我想反转它，使 1 为 -1，而 -1 为 1。如何使用处理软件来做到这一点？

Answer 1

Nikos 是正确的，您正在寻找的操作称为反转而不是反转。这只需将每个样本乘以 -1 即可实现。

最好的方法是使用处理的音频库 Minim。您可以扩展 UGen 类以创建一个新的效果处理器，该处理器可以翻转通过它的每个样本。我在下面提供了一个适用于正弦波的示例。您可以将其更改为其他音频源并根据需要进行绘制。

import ddf.minim.*;
import ddf.minim.ugens.*;

Minim minim;
AudioOutput out;

void setup()
{
  size(300, 200, P2D);

  minim = new Minim(this);
  out = minim.getLineOut();

  Oscil osc;
  Invert inv;
  Constant cutoff;

  // initialize the oscillator 
  // (a sawtooth wave has energy across the spectrum)
  osc = new Oscil(500, 0.2, Waves.SINE);  
  inv = new Invert();
  osc.patch(inv).patch(out);
}

void draw()
{
  background( 0 );

}

public class Invert extends UGen{

  public UGenInput audio;

  Invert()
  {
    audio = new UGenInput(InputType.AUDIO);
  }

  @Override
  protected void uGenerate (float[] channels)
  {
    if ( audio.isPatched() )
    {
      for (int i = 0; i < channels.length; i++){
        // this is where we multiple each sample by -1
        channels[i] = audio.getLastValues()[i] * -1;
      } 
    }  
  }
}