2

我有关于 VBA 和控制/操作新窗口的三个问题。

我设置了几张床单。

硕士 | 工作表1 | 工作表2 | 笔记 | 工单 | 联系方式

1) 我在 Notes、Work Orders、Contact Info 上设置了 WorkSheet_Activate 函数，这些函数在单独的窗口中打开所有三张工作表并垂直排列它们。

Private Sub WorkSheet_Activate()

    ActiveWindow.NewWindow
    ActiveWindow.NewWindow
    Windows.Arrange ArrangeStyle:=xlVertical
    Sheets("Notes").Select
    Windows("Mastersheet.xlsm:2").Activate
    Sheets("Work Orders").Select
    Windows("Mastersheet.xlsm:1").Activate
    Sheets("Contact Info").Select

End Sub

问题在于，如果我可以再次激活这些工作表，它将打开更多窗口。我想要代码来检测窗户是否已经打开，如果是，则打破。

2）现在，当我导航到不同的工作表（例如 Master）时，我希望关闭额外的窗口并让 Master 工作表处于活动状态。我在主表上使用以下代码。

Private Sub WorkSheet_Activate()


    Windows("Mastersheet.xlsm:2").Activate
    ActiveWindow.Close
    Windows("Mastersheet.xlsm:1").Activate
    ActiveWindow.Close
    ActiveWindow.WindowState = xlMaximized

End Sub

这段代码的问题是，如果额外的窗口没有打开，那么它会出错。我可以进行某种逻辑检查以使其正常工作吗？我不知道要检查什么值...

3）最后一个问题是工作簿中的宏动态生成了新的工作表。那些新的工作表不会携带上述关闭多个窗口并专注于活动表的代码。是否应该将代码放入其他对象以使其适用于 Master | 工作表1 | Worksheet2 工作表和任何新工作表？

4

2 回答 2

6

这是很多问题。:) 对于 3，您需要将事件从它们所在的位置移到处理应用程序级事件的自定义类模块中。首先在您的项目中插入一个新的类模块（插入 - 类模块）。将该模块命名为 CAppEvents（F4 显示属性表，您可以在其中更改名称）。然后将此代码粘贴到类模块中

Option Explicit

Private WithEvents mobjWb As Workbook

Private Sub Class_Terminate()

    Set mobjWb = Nothing

End Sub

Public Property Get wb() As Workbook

    Set wb = mobjWb

End Property

Public Property Set wb(objwb As Workbook)

    Set mobjWb = objwb

End Property

Private Sub mobjWb_SheetActivate(ByVal Sh As Object)

    Dim wn As Window

    If IsSplitSheet(Sh) Then
        If Not IsSplit(Sh) Then
            CreateSplitSheets Sh
        End If
    Else
        If IsSplit(Sh) Then
            For Each wn In Me.wb.Windows
                If wn.Caption Like Me.wb.Name & ":#" Then
                    wn.Close
                End If
            Next wn
            ActiveWindow.WindowState = xlMaximized
            Sh.Activate
        End If
    End If

End Sub

Private Function IsSplitSheet(Sh As Object) As Boolean

    Dim vaNames As Variant
    Dim i As Long

    IsSplitSheet = False
    vaNames = GetSplitSheetNames

    For i = LBound(vaNames) To UBound(vaNames)
        If vaNames(i) = Sh.Name Then
            IsSplitSheet = True
            Exit For
        End If
    Next i

End Function

Private Function IsSplit(Sh As Object) As Boolean

    Dim wn As Window

    IsSplit = False

    For Each wn In Me.wb.Windows
        If wn.Caption Like Sh.Parent.Name & ":#" Then
            IsSplit = True
            Exit For
        End If
    Next wn

End Function

Private Sub CreateSplitSheets(Sh As Object)

    Dim vaNames As Variant
    Dim i As Long
    Dim wn As Window
    Dim wnActive As Window

    vaNames = GetSplitSheetNames
    Set wnActive = ActiveWindow

    For i = LBound(vaNames) To UBound(vaNames)
        If vaNames(i) <> Sh.Name Then
            Set wn = Me.wb.NewWindow
            wn.Activate
            On Error Resume Next
                wn.Parent.Sheets(vaNames(i)).Activate
            On Error GoTo 0
        End If
    Next i

    Sh.Parent.Windows.Arrange xlVertical
    wnActive.Activate
    Sh.Activate

End Sub

Private Function GetSplitSheetNames() As Variant

    GetSplitSheetNames = Array("Notes", "Work Orders", "Contact Info")

End Function

然后插入一个标准模块（Insert - Module）并粘贴此代码

Option Explicit

Public gclsAppEvents As CAppEvents

Sub Auto_Open()

    Set gclsAppEvents = New CAppEvents
    Set gclsAppEvents.wb = ThisWorkbook

End Sub

这是发生的事情：当您打开工作簿时，Auto_Open 将运行，它会创建您的 CAppEvents 对象的新实例。由于 gclsAppEvents 是公共的（也称为全局），只要工作簿处于打开状态，它就不会失去作用域。它将坐在那里监听事件（因为我们在类中使用了 WithEvents 关键字）。

在类中有一个名为 mobjWb_SheetActivate 的子程序。每当激活此工作簿中的任何工作表时，都会触发此内容。首先，它检查您刚刚激活的工作表（Sh 变量）是否是您要拆分的工作表之一（使用 IsSplitSheet）。如果是，它会检查它是否已经被分割。如果没有，它会将它们分开。

如果 Sh（您刚刚激活的工作表）不是“拆分表”之一，则它会检查是否已完成拆分 (IsSplit)。如果有，它会关闭所有拆分窗口。

如果您甚至想要添加、更改或删除导致拆分的工作表，请转到 GetSplitSheetNames 函数并更改 Array 参数。

因为我们使用自定义类并在工作簿级别嗅探事件，所以您可以随心所欲地添加和删除工作表。

于 2010-01-21T22:44:15.720 回答
1

1）要测试一个窗口是否已经打开，使用这个函数

Function IsWindowOpen(windowTitle As String) As Boolean
    Dim i As Long
    For i = 1 To Windows.Count
        If Windows(i).Caption = windowTitle Then
            IsWindowOpen = True
            Exit Function
        End If
    Next
    IsWindowOpen = False
End Function

例如：

if not IsWindowOpen("Mastersheet.xlsm:2") then
     ' code to open windows
end if

2）您可以再次重用该功能，同样的想法：

if IsWindowOpen("Mastersheet.xlsm:2") then
     ' code to close windows
end if

3）将您的代码添加到模块，而不是工作表。然后在完成此操作后从添加新工作表的宏中调用例程。如果此宏位于不同的模块中，您可能必须确保您的 Sub 是公开的。

于 2010-01-21T22:20:36.030 回答