2

我正在使用 LLVM-IR 代码，它由生成clang -emit-llvm并希望使代码折叠工作。

到目前为止，我正在使用foldmethod=exprand foldexpr=LLVMFold()。我想使用foldmethod=syntax来自 llvm 存储库的语法文件来使用基于语法的折叠（即）。在这里可用。

请注意，第一个正则表达式来自标签的语法文件。

function! LLVMFolds()
    let thisline = getline(v:lnum)
    if match(thisline, '^[-a-zA-Z$._][-a-zA-Z$._0-9]*:') >= 0
        return ">2"
    elseif match(thisline, '^\}$') >= 0
        return "<1"
    elseif match(thisline, '{$') >= 0
        return ">1"
    else
        return "="
    endif
endfunction

它将闭合大括号吞噬到 2 级折叠中。

还尝试了foldmethod=indent哪些折叠不够，并且foldmethod=marker对于foldmark="{,}" 这个示例不完整的 LLVM-IR 代码来说理想情况下：

define i32 @main() nounwind {
entry:
  %retval = alloca i32, align 4

for.cond:                                         ; preds = %entry
  %4 = load i32* %i, align 4
  %cmp1 = icmp slt i32 %4, 10
  br i1 %cmp1, label %for.body, label %for.end
}

我希望在每个标记的部分中折叠从 the{到definethe }，即从 theentry:到清晰线。

4

2 回答 2

1

我不认为

:set foldmethod=syntax

将帮助您链接中的语法文件，因为该文件没有定义任何fold参数。

您的LLVMFolds()功能似乎几乎可以满足您的需求，但是（如果我理解正确的话）您不希望折叠包含该}行。也许您想要的是使上一行结束折叠，如下所示：

function! Foo(lnum)
    let thisline = getline(v:lnum)
    let nextline = getline(v:lnum + 1)
    if match(thisline, '^[-a-zA-Z$._][-a-zA-Z$._0-9]*:') >= 0
        return ">2"
    elseif match(nextline, '^\}$') >= 0
        return "<1"
    elseif match(thisline, '{$') >= 0
        return ">1"
    else
        return "="
    endif
endfunction

{如果和之间没有线，这可能会也可能不会做你想做的事}。出于测试目的，请尝试

:set fdm=expr foldexpr=LLVMFolds() fdc=5

参考：

:help fold-syntax
:help :syn-fold
:help fold-expr
于 2014-01-08T05:08:31.403 回答
0

我现在已经使用了这个功能

function! LLVMFolds()
    let thisline = getline(v:lnum)
    let nextline = getline(v:lnum + 1)
    " match start of global var block
    if match(thisline, '^@') == 0 && foldlevel(v:lnum - 1) <= 0
        return ">1"
    " match start of global struct block
    elseif match(thisline, '^%') == 0 && foldlevel(v:lnum - 1) <= 0
        return ">1"
    " matches lables
    elseif match(thisline, '^[-a-zA-Z$._][-a-zA-Z$._0-9]*:') >= 0
        return ">2"
    " keep closing brace outside  l2 fold
    elseif match(nextline, '^\}$') >= 0
        return "<2"
    " keep closing brace in l1 fold
    elseif match(thisline, '^\}$') >= 0
        return "<1"
    " open new l1 fold for open brace
    elseif match(thisline, '{$') >= 0
        return ">1"
    " for the next line being empty, close the fold for the var and struct blocks
    elseif match(nextline, '^$') >= 0
        if match(thisline, '^@') == 0 && foldlevel(v:lnum - 1) == 1
            return "<1"
        elseif match(thisline, '^%') >= 0 && foldlevel(v:lnum - 1) == 1
            return "<1"
        else
            return "="
        endif
    else
        return "="
    endif
endfunction

它从第 2 级折叠中排除右括号，并折叠全局结构和变量的初始列表。

于 2014-01-09T00:35:52.343 回答