3

这是一个客户端服务器应用程序。我正在创建一个更新程序，它将替换 exe 文件列表、运行脚本以及任何其他需要更新的内容。这将安装在服务器上。

首先我需要检查可执行文件是否通过网络共享打开。我可以通过进入计算机管理然后共享文件和打开文件来手动执行此操作。这似乎是检查文件是否打开的唯一方法。我尝试使用 R/W 检查文件是否已打开，但这不起作用。查看 Win32_ServerConnection 但这只是列出了打开的文件数而不是名称。

如果不能在 Delphi 中完成，我想在 Delphi 7 或 C# 中编写代码。我发现了一些可以查看服务器上打开文件的程序，但没有关于如何做到这一点。

4

5 回答 5

2

在 Windows 2000 及更高版本上，您可以使用NetFileEnum API：

program test;

{$APPTYPE CONSOLE}

uses
  Windows,
  Classes,
  SysUtils;

type
  PFileInfo3 = ^TFileInfo3;
  TFileInfo3 = record
    fi3_id: DWORD;
    fi3_permissions: DWORD;
    fi3_num_locks: DWORD;
    fi3_pathname: PWideChar;
    fi3_username: PWideChar;
  end;

  TNetFileEnumCallback = function(const FileInfo: TFileInfo3; Data: Pointer): Boolean;

const
  netapi = 'netapi32.dll';

function NetApiBufferFree(Buffer: Pointer): DWORD; stdcall; external netapi;
function NetFileEnum(servername: PWideChar; basepath: PWideChar; username: PWideChar; level: DWORD; var bufptr: Pointer;
  prefmaxlen: DWORD; var entriesread: DWORD; var totalentries: DWORD; resume_handle: PDWORD): DWORD; stdcall;
  external netapi;

procedure EnumNetFileUsers(const LocalPath: WideString; Callback: TNetFileEnumCallback; Data: Pointer = nil);
const
  EntryCount = 32;
var
  NetResult, EntriesRead, TotalEntries, ResumeHandle: Cardinal;
  Buf: Pointer;
  P: PFileInfo3;
  I: Integer;
begin
  EntriesRead := 0;               
  TotalEntries := 0;
  ResumeHandle := 0;
  repeat
    NetResult := NetFileEnum(nil, PWideChar(LocalPath), nil, 3, Buf, EntryCount * SizeOf(TFileInfo3), EntriesRead,
      TotalEntries, @ResumeHandle);
    if not (NetResult in [ERROR_SUCCESS, ERROR_MORE_DATA]) then
      RaiseLastOSError(NetResult);
    try
      P := Buf;
      for I := 0 to EntriesRead - 1 do
      begin
        if Callback(P^, Data) then
          Break;

        Inc(P);
      end;
    finally
      NetApiBufferFree(Buf);
    end;
  until NetResult = ERROR_SUCCESS;
end;

function ShowFileInfo(const FileInfo: TFileInfo3; Data: Pointer): Boolean;
begin
  Result := False;
  Writeln(Format('id: %d, permissions: $%.8x, num_locks: %d, pathname: ''%s'', username: ''%s''',
    [FileInfo.fi3_id, FileInfo.fi3_permissions, FileInfo.fi3_num_locks, FileInfo.fi3_pathname, FileInfo.fi3_username]));
end;

begin
  try
    if ParamCount = 1 then
      EnumNetFileUsers(ParamStr(1), ShowFileInfo);
  except
    on E: Exception do
    begin
      Writeln(Format('[%s] %s', [E.ClassName, E.Message]));
      ExitCode := 1;
    end;
  end;
end.

似乎LocalPath参数中传递的路径必须以双反斜杠开头，例如：

test.exe C:\\Dev\Test\test.exe

产生以下输出（如果文件是通过共享打开的）：

id: -469761405, permissions: $00000001, num_locks: 0, pathname: 'C:\\Dev\Test\test.exe', username: 'Ondrej'

另请注意，MSDN 说：

“只有 Administrators 或 Server Operators 本地组的成员才能成功执行 NetFileEnum 函数。”

于 2010-01-19T21:54:45.143 回答
2

为什么不尝试删除它？如果文件当前处于打开状态，您将收到错误消息。如果删除它有效，您只需复制更新的可执行文件。

于 2010-01-19T19:46:59.153 回答
1

您可以保留将在其上运行的“服务器”的静态列表，您可以查找进程机器名称、主机名或计算机名称以进行匹配。如果它在列表中，您可以假设它是本地开放的。

string name = Environment.MachineName;
string name = System.Net.Dns.GetHostName();
string name = System.Windows.Forms.SystemInformation.ComputerName;

Process[] myProcesses = Process.GetProcessesByName("myExeProcName",MachineName);
foreach(Process myProcess in myProcesses)
{
    Console.Write("MachineName : " + myProcess.MachineName + "\n");
}
于 2010-01-19T20:28:05.560 回答
1

我使用这样的函数来检查是否可以更改文件系统上的文件。基本上我尝试“创建”一个名为 fName 的新文件，仍然打开现有的（如果它存在的话）并获得一个有效的文件句柄。如果失败，则该文件正在使用中。该函数实际上并没有创建文件，也没有改变现有的文件系统（我从不使用句柄做任何事情）。它只是检查我是否可以获得文件的文件句柄，如果我想对它做点什么。

这也适用于从远程计算机上的共享中打开的文件。

 function IsFileInUse(fName: string): boolean;
  var
    HFileRes: HFILE;
  begin
    Result := false;
    if not FileExists(fName) then
      exit;
    HFileRes := CreateFile(pchar(fName),
      GENERIC_READ or GENERIC_WRITE,
      0, nil, OPEN_EXISTING,
      FILE_ATTRIBUTE_NORMAL,
      0);
    Result := (HFileRes = INVALID_HANDLE_VALUE);
    if not Result then
      CloseHandle(HFileRes);
  end;
于 2010-01-20T00:07:28.927 回答
-1

你见过 System.IO 中的 FileSystemWatcher 吗？

http://msdn.microsoft.com/en-us/library/system.io.filesystemwatcher.aspx

于 2010-01-19T19:39:54.097 回答