delphi - Delphi TListBox OnClick / OnChange？

Question

使用 TListBox 获得“OnChange”类型的功能是否有技巧？我可以对组件进行子类化并添加属性等，然后仅在索引更改时才执行 OnClick 代码...我还可以使用表单级别变量对其进行破解以存储当前索引，但只是想知道我是否忽略了之前的明显情况我去一种或另一种方式。

Answer 1

似乎除了自己实现之外别无他法。您需要记住当前选择的项目，并且无论何时ItemIndex从代码更改属性或每当控件接收到LBN_SELCHANGE通知（当前触发OnClick事件）时，您将存储的项目索引与当前选择的项目索引进行比较，如果他们不同，触发你自己的OnChange事件。在插入类的代码中，它可能是：

type
  TListBox = class(StdCtrls.TListBox)
  private
    FItemIndex: Integer;
    FOnChange: TNotifyEvent;
    procedure CNCommand(var AMessage: TWMCommand); message CN_COMMAND;
  protected
    procedure Change; virtual;
    procedure SetItemIndex(const Value: Integer); override;
  published
    property OnChange: TNotifyEvent read FOnChange write FOnChange;
  end;

implementation

{ TListBox }

procedure TListBox.Change;
begin
  if Assigned(FOnChange) then
    FOnChange(Self);
end;

procedure TListBox.CNCommand(var AMessage: TWMCommand);
begin
  inherited;
  if (AMessage.NotifyCode = LBN_SELCHANGE) and (FItemIndex <> ItemIndex) then
  begin
    FItemIndex := ItemIndex;
    Change;
  end;
end;

procedure TListBox.SetItemIndex(const Value: Integer);
begin
  inherited;
  if FItemIndex <> ItemIndex then
  begin
    FItemIndex := ItemIndex;
    Change;
  end;
end;

Answer 2

与 OnClick 事件就是这样......你需要存储最后一个值来比较它。

if ListBox1.Items[ListBox1.ItemIndex]<> Edit1.Text then
    Edit1.Text := ListBox1.Items[ListBox1.ItemIndex];