11

我的意思是单个二进制文件可以在 Win32 和 Linux i386 中运行吗？

4

3 回答 3

24

这是不可能的，因为这两种类型有冲突的格式：

  • PE 文件的前两个字符必须是'M' 'Z';
  • ELF 文件的前四个字符必须是'\x7f' 'E' 'L' 'F'.

显然，您无法创建一个同时满足这两种格式的文件。

作为对多语言二进制文件同时作为 16 位 COM 文件和 Linux ELF 文件有效的评论的回应，这是可能的（尽管 COM 文件实际上是 DOS 程序，而不是 Windows - 当然也不是 Win32）。

这是我拼凑的一个 - 用 NASM 编译它。它之所以有效，是因为 ELF 文件 ( '\x7f' 'E') 的前两个字节恰好也是有效的 8086 机器代码（一个 45 字节的相对跳转-if-greater-than 指令）。从Brian Raiter 抄袭的最小 ELF 标头。

BITS 32
ORG 0x08048000

  ehdr:                                                 ; Elf32_Ehdr
                db      0x7F, "ELF", 1, 1, 1, 0         ;   e_ident
        times 8 db      0
                dw      2                               ;   e_type
                dw      3                               ;   e_machine
                dd      1                               ;   e_version
                dd      _start                          ;   e_entry
                dd      phdr - $$                       ;   e_phoff
                dd      0                               ;   e_shoff
                dd      0                               ;   e_flags
                dw      ehdrsize                        ;   e_ehsize
                dw      phdrsize                        ;   e_phentsize
                dw      1                               ;   e_phnum
                dw      0                               ;   e_shentsize
                dw      0                               ;   e_shnum
                dw      0                               ;   e_shstrndx
  ehdrsize      equ     $ - ehdr

times 0x47-($-$$) db    0

; DOS COM File code
BITS 16
    mov dx, msg1 - $$ + 0x100
    mov ah, 0x09
    int 0x21
    mov ah, 0x00
    int 0x21
  msg1:         db      `Hello World (DOS).\r\n$`

BITS 32
  phdr:                                                 ; Elf32_Phdr
                dd      1                               ;   p_type
                dd      0                               ;   p_offset
                dd      $$                              ;   p_vaddr
                dd      $$                              ;   p_paddr
                dd      filesize                        ;   p_filesz
                dd      filesize                        ;   p_memsz
                dd      5                               ;   p_flags
                dd      0x1000                          ;   p_align
  phdrsize      equ     $ - phdr

; Linux ELF code
  _start:
    mov eax, 4      ; SYS_write
    mov ebx, 1      ; stdout
    mov ecx, msg2
    mov edx, msg2_len
    int 0x80
    mov eax, 1      ; SYS_exit
    mov ebx, 0
    int 0x80
  msg2:         db      `Hello World (Linux).\n`
  msg2_len      equ     $ - msg2

  filesize      equ     $ - $$
于 2010-01-17T23:52:44.787 回答
2

这两种格式完全不同，不太可能混合使用。

但是，Linux 支持通过“解释器”加载不同的可执行格式。例如，通过这种方式.exe，包含 CIL（编译的 C# 或其他 .NET 语言）的编译文件可以直接在 Linux 下执行。

于 2010-01-17T19:49:03.880 回答
-1

当然。使用 Java。

于 2010-01-17T19:48:38.143 回答