3

给定一个嵌套向量 A

[[1 2 3] [4 5 6] [7 8 9]]

我的目标是循环移动行和列。

如果我首先考虑单行移位，我希望

[[7 8 9] [1 2 3] [4 5 6]]

在这种情况下，第三行映射到第一行。

这是由代码实现的

(defn circles [x i j]
     (swap-rows x i j))

带输入

(circles [[1 2 3] [4 5 6] [7 8 9]] 0 1)

但是，我不确定如何进一步移动列。理想情况下，我想添加到函数圈并能够移动行或列。虽然我不确定对于每个班次选择是否只有两个不同的功能是最简单的。

4

3 回答 3

4 
(defn circles [xs i j]
  (letfn [(shift [v n]
            (let [n (- (count v) n)]
              (vec (concat (subvec v n) (subvec v 0 n)))))]
    (let [ys (map #(shift % i) xs)
          j  (- (count xs) j)]
      (vec (concat (drop j ys) (take j ys))))))

例子：

(circles [[1 2 3] [4 5 6] [7 8 9]] 1 1)
;= [[9 7 8] [3 1 2] [6 4 5]]

根据您希望执行此操作的频率、输入向量的大小和要应用的移位，使用core.rrb-vector可能是有意义的。clojure.core.rrb-vector/catvec是相关函数（您也可以clojure.core.rrb-vector/subvec用于切片，但实际上这里可以使用常规subvecfrom clojure.core，因为catvec它将执行自己的转换）。

于 2013-12-27T18:57:40.060 回答
2

您还可以使用循环：

(defn circle-drop [i coll]
  (->> coll
       cycle
       (drop i)
       (take (count coll))
       vec))

(defn circles [coll i j]
  (let [n (count coll)
        i (- n i)
        j (- n j)]
    (->> coll
         (map #(circle-drop i %))
         (circle-drop j))))

(circles [[1 2 3] [4 5 6] [7 8 9]] 2 1)
;; => [[8 9 7] [2 3 1] [5 6 4]]
于 2013-12-27T19:57:59.743 回答
2

有一个函数用于调用rotate（core.matrix通用数组/矩阵操作通常是这种情况）

第二个参数rotate让您选择要旋转的维度（0 表示行，1 表示列）

(use 'clojure.core.matrix)

(def A [[1 2 3] [4 5 6] [7 8 9]])

(rotate A 0 1)
=> [[4 5 6] [7 8 9] [1 2 3]]

(rotate A 1 1)
=> [[2 3 1] [5 6 4] [8 9 7]]
于 2013-12-27T23:55:51.603 回答