4

我有一个简单的 LALR(1) 语法，但我遇到了问题。

start ::= spec.
spec ::= MOD STRING top_stmt.
spec ::= top_stmt.
top_stmt ::= stmt.
top_stmt ::= conditional.
stmt ::= expr.
stmt ::= assignment.
conditional ::= IF stmt_list.
expr ::= retval.
expr ::= NOT retval.
retval ::= access.
retval ::= invoke.
access ::= ns_identifier OBJECT_OPERATOR property_chain.
access ::= ns_identifier.
ns_identifier ::= identifier.
ns_identifier ::= ns_identifier NS_SEPARATOR identifier.
ns_identifier ::=.
property_chain ::= property_chain OBJECT_OPERATOR identifier.
property_chain ::= identifier.
identifier ::= VARIABLE.
identifier ::= STRING.
assignment ::= access ASSIGN expr. [ASSIGN]
stmt_list ::= stmt.
stmt_list ::= stmt_list COMMA stmt. [COMMA]
invoke ::= access LPAREN empty_stmt_list RPAREN.
empty_stmt_list ::=.
empty_stmt_list ::= stmt.
empty_stmt_list ::= empty_stmt_list COMMA stmt. [COMMA]

点标记规则的结束，括号之间的终端具有关联性：ASSIGN 是右关联的，COMMA 是左关联的。

但是柠檬说它不能减少规则“empty_stmt_list ::=”。因为它没有连接到开始符号。我敢打赌 ：-）

“invoke”也存在解析冲突，当empty_stmt_list确实是一个empy语句列表时，它无法在RPAREN和COMMA之间做出决定。

我想要实现的是能够解析没有（void）参数的函数调用。

其他一切都按预期工作。

谢谢

编辑：我已经编辑了我的原始帖子并发布了整个精简的语法。

4

2 回答 2

4

你的第一个问题是我不认为这个位做你想要的：

invoke ::= access LPAREN empty_stmt_list RPAREN.
empty_stmt_list ::=.
empty_stmt_list ::= stmt.
empty_stmt_list ::= empty_stmt_list COMMA stmt. [COMMA]

生产将invokematch access LPAREN COMMA stmt RPAREN，我认为这是不可取的（并且是 LPAREN/COMMA 冲突的来源）。

您可以像这样使用现有stmt_list规则来解决此问题：

invoke ::= access LPAREN maybe_empty_stmt_list RPAREN.
maybe_empty_stmt_list ::= .
maybe_empty_stmt_list ::= stmt_list.

那仍然报告冲突（但现在只有 1 个）并且仍然抱怨maybe_empty_stmt_list ::=.无法减少。因此，在 XXX.out 文件中查看它是什么：

State 2:
...
     (16) ns_identifier ::= *
...
     (25) maybe_empty_stmt_list ::= *
...
                        RPAREN reduce 25  ** Parsing conflict **
....
                     {default} reduce 16

...看来问题出在ns_identifier ::=.规则上。回顾所涉及的产品，不难看出可以将空ns_identifier归为stmt_list（通过ns_identifier-> access-> retval-> expr-> stmt-> stmt_list）。

这就解释了冲突；并且该ns_identifier ::=.规则在这种情况下受到青睐，因为它出现在语法的早期（请参阅文档中解决reduce-reduce冲突的规则，解释了为什么它抱怨该maybe_empty_stmt_list ::=.规则永远无法减少。

于 2010-01-16T22:55:37.587 回答
0

您可以尝试为 LPAREN/COMMA 添加优先规则，并检查它是否会影响其他地方的语义。

于 2010-01-16T18:12:52.303 回答