4

我有一个包含员工姓名和他们完成的工作的 XML 文件。XML 文件的结构是 -

<Employee>AAA@A#B#C#D</Employee>
<Employee>BBB@A#B#C#D</Employee>
<Employee>CCC@A#B#C#D</Employee>
<Employee>DDD@A#B#C#D</Employee>

有数千条记录，我必须将结构更改为 -

<Employee>
  <Name>AAA</Name>
  <Jobs>
   <Job>A</Job>
   <Job>B</Job>
   <Job>C</Job>
   <Job>D</Job>
  </Jobs>
</Employee>

如何在 BaseX 中使用 XQuery 完成这项工作？

4

2 回答 2

4

3 个 XQuery 函数、substring-before和substring-after用于tokenize获取所需的输出。

substring-before用于获取名称。

同样，substring-after用于获取 Job 部分。

然后该tokenize函数用于拆分作业。

let $data :=
  <E>
    <Employee>AAA@A#B#C#D</Employee>
    <Employee>BBB@A#B#C#D</Employee>
    <Employee>CCC@A#B#C#D</Employee>
    <Employee>DDD@A#B#C#D</Employee>
  </E>


for $x in $data/Employee
return 

<Employee>
   {<Name>{substring-before($x,"@")}</Name>}
   {<Jobs>{
   for $tag in tokenize(substring-after($x,"@"),'#')
   return 
     <Job>{$tag}</Job>
   }</Jobs>
}</Employee>

HTH...

于 2013-12-23T06:18:38.530 回答
2

标记字符串可能更容易和更快。使用正则表达式tokenize($string, $pattern)拆分，返回序列的第一个值以及除第一个之外的所有值。当然，您也可以使用位置谓词，但这些函数更易于阅读。$string$patternhead($seq)tail($seq)

for $employee in //Employee
let $tokens := tokenize($employee, '[@#]')
return element Employee {
  element Name { head($tokens) },
  element Jobs {
    for $job in tail($tokens)
    return element Job { $job }
  }
}
于 2013-12-23T11:48:07.043 回答