15

我一直在尝试了解应用函子的静态分析。许多消息来源说，与 monad 相比，使用它们的一个优势是对静态分析的敏感性。

然而，我能找到的唯一一个实际执行静态分析的例子太复杂了，我无法理解。有没有更简单的例子？

具体来说，我想知道我是否可以对递归应用程序执行静态分析。例如，类似：

y = f <$> x <*> y <*> z

分析上面的代码，有没有可能检测到它在y上是递归的？还是参考透明度仍然阻止这成为可能？

4

2 回答 2

16

应用函子允许在运行时进行静态分析。这可以通过一个更简单的例子来更好地解释。

想象一下，您想计算一个值，但想跟踪该值所具有的依赖关系。例如，您可以IO a用来计算值，并有一个Strings依赖项列表：

data Input a = Input { dependencies :: [String], runInput :: IO a }

现在我们可以轻松地将其设为Functorand的实例Applicative。函子实例是微不足道的。由于它没有引入任何新的依赖项，您只需要映射该runInput值：

instance Functor (Input) where
  fmap f (Input deps runInput) = Input deps (fmap f runInput)

实例比较Applicative复杂。该pure函数将只返回一个没有依赖关系的值。组合器<*>将连接两个依赖项列表（删除重复项），并组合两个操作：

instance Applicative Input where
  pure = Input [] . return

  (Input deps1 getF) <*> (Input deps2 runInput) = Input (nub $ deps1 ++ deps2) (getF <*> runInput)

有了这个，我们也可以创建一个Input aNum 的实例，如果Num a：

instance (Num a) => Num (Input a) where
  (+) = liftA2 (+)
  (*) = liftA2 (*)
  abs = liftA abs
  signum = liftA signum
  fromInteger = pure . fromInteger

接下来，让我们做几个输入：

getTime :: Input UTCTime
getTime = Input { dependencies = ["Time"], runInput = getCurrentTime }

-- | Ideally this would fetch it from somewhere
stockPriceOf :: String -> Input Double
stockPriceOf stock = Input { dependencies = ["Stock ( " ++ stock ++ " )"], runInput = action } where
  action = case stock of
    "Apple" -> return 500
    "Toyota" -> return 20

最后，让我们创建一个使用一些输入的值：

portfolioValue :: Input Double
portfolioValue = stockPriceOf "Apple" * 10 + stockPriceOf "Toyota" * 20

这是一个很酷的值。首先，我们可以找到portfolioValue作为纯值的依赖关系：

> :t dependencies portfolioValue
dependencies portfolioValue :: [String]
> dependencies portfolioValue
["Stock ( Apple )","Stock ( Toyota )"]

那是Applicative允许的静态分析 - 我们知道依赖关系而无需执行操作。

尽管如此，我们仍然可以获得动作的价值：

> runInput portfolioValue >>= print
5400.0

现在，为什么我们不能做同样的事情Monad呢？原因是Monad可以表达选择，因为一个动作可以决定下一个动作是什么。

想象一下，有一个Monad接口Input，你有以下代码：

mostPopularStock :: Input String
mostPopularStock = Input { dependencies ["Popular Stock"], getInput = readFromWebMostPopularStock }

newPortfolio = do
  stock <- mostPopularStock
  stockPriceOf "Apple" * 40 + stockPriceOf stock * 10

现在，我们如何计算 的依赖关系newPortolio？事实证明，如果不使用 IO，我们就无法做到这一点！这将取决于最受欢迎的股票，唯一知道的方法是运行 IO 操作。因此，当类型使用 Monad 时，不可能静态跟踪依赖关系，但仅使用 Applicative 就完全可以。这是一个很好的例子，说明为什么通常更少的功率意味着更有用 - 因为 Applicative 不允许选择，所以可以静态计算依赖关系。

编辑：关于检查y自身是否递归，如果您愿意注释函数名称，则可以使用应用函子进行此类检查。

data TrackedComp a = TrackedComp { deps :: [String],  recursive :: Bool, run :: a}

instance (Show a) => Show (TrackedComp a) where
  show comp = "TrackedComp " ++ show (run comp)

instance Functor (TrackedComp) where
  fmap f (TrackedComp deps rec1 run) = TrackedComp deps rec1 (f run)

instance Applicative TrackedComp where
  pure = TrackedComp [] False

  (TrackedComp deps1 rec1 getF) <*> (TrackedComp deps2 rec2 value) =
    TrackedComp (combine deps1 deps2) (rec1 || rec2) (getF value)

-- | combine [1,1,1] [2,2,2] = [1,2,1,2,1,2]
combine :: [a] -> [a] -> [a]
combine x [] = x
combine [] y = y
combine (x:xs) (y:ys) = x : y : combine xs ys

instance (Num a) => Num (TrackedComp a) where
  (+) = liftA2 (+)
  (*) = liftA2 (*)
  abs = liftA abs
  signum = liftA signum
  fromInteger = pure . fromInteger

newComp :: String -> TrackedComp a -> TrackedComp a
newComp name tracked = TrackedComp (name : deps tracked) isRecursive (run tracked) where
   isRecursive = (name `elem` deps tracked) || recursive tracked 


y :: TrackedComp [Int]
y = newComp "y" $ liftA2 (:) x z

x :: TrackedComp Int
x = newComp "x" $ 38

z :: TrackedComp [Int]
z = newComp "z" $ liftA2 (:) 3 y

> recursive x
False
> recursive y
True
> take 10 $ run y
[38,3,38,3,38,3,38,3,38,3]
于 2013-12-15T03:52:40.960 回答
3

是的，应用函子比单子允许更多的分析。但是不，你不能观察到递归。我写了一篇关于解析的论文，详细解释了这个问题：

https://lirias.kuleuven.be/bitstream/123456789/352570/1/gc-jfp.pdf

然后，本文讨论了另一种递归编码，它确实允许分析，并具有一些其他优点和一些缺点。其他相关工作是：

https://lirias.kuleuven.be/bitstream/123456789/376843/1/p97-devriese.pdf

更多相关工作可以在这些论文的相关工作部分中找到......

于 2013-12-15T09:17:42.163 回答