triggers - Apex 触发器 - 使用数据加载器时的值不正确

Question

我在帐户对象上有一个字段，在编辑帐户时会更新。单独编辑记录时，会将正确的值写入字段。当我使用数据加载器时。. . 一个值适用于所有记录。这是我的触发器，请指教。

trigger Populate_Transfer_Manager on Account (before insert, before Update) {   

    list<id> aid = new list<id>();
    for(account a: trigger.new){           
        aid.add(a.ownerid);
    }

list<user> managers = new list<user>();
    managers = [select managerid from user where id in: aid];


set<id> manid = new set<id>();                             
    for(user u: managers){
        manid.add(u.managerid);
    }


for(account a: trigger.new){        
    for(id i: manid){           
            a.transfer_manager__c = i;       
        }
    }
}

Answer 1

触发器只为每批 200 次触发一次，并将值分配给该批中的所有记录。使用地图，我能够为数据库中的所有记录分配正确的值。

trigger Populate_Transfer_Manager on Account (before insert, before Update) {    

    list<id> aid = new list<id>();
    for(account a: trigger.new){                   
        aid.add(a.ownerid);
            }
    map<id, user> users = new map<id, user>(
        [select managerid from user where id in: aid]);

    for(account a: trigger.new){
        a.Transfer_Manager__c = users.get(a.ownerid).managerid;
    }
}