7

我正在设置我的 Subversion 提交后挂钩以在提交时远程触发 Jenkins 构建。

首先我改为post-commit.tmpl然后post-commit.bat：

我首先尝试了这个：

SET REPOS=%1
SET REV=%2
C:/wget_for_win/wget http://localhost:8080/jenkins/job/my_project/build

然后我提交了一些代码，它按预期工作。但这只会构建一个项目，但我希望它更灵活，所以我更改post-commit.bat为我在Jenkins Subversion 插件页面上找到的那个：

SET REPOS=%1
SET REV=%2
SET UUID=`svnlook uuid %REPOS%`
C:/wget_for_win/wget \
 --header="Content-Type:text/plain;charset=UTF-8"
 --post-data="svnlook changed --revision %REV% %REPOS%"
 --output-document="-"
 --timeout=2
 http://localhost:8080/jenkins/subversion/%UUID%/notifyCommit?rev=%REV%

但是这个不行。它没有触发 Jenkins 继续构建。我在第二个脚本中做错了什么？

我认为在批处理文件中运行“svnlook”时存在问题。我svnlook uuid [REPO LOCATION]在cmd中运行，它显示了id。然后我把它放在一个批处理文件中：

SET UUID=svnlook uuid [REPO LOCATION]
ECHO %UUID%

运行上述批处理文件不会输出 id。它显示只是svnlook uuid [REPO LOCATION].

4

1 回答 1

6

最后我的post-commit.bat样子：

SET REPOS=%1
SET REV=%2

FOR /f "tokens=*" %%a IN (
'svnlook uuid %REPOS%'
) DO (
SET UUID=%%a
)

FOR /f "tokens=*" %%b IN (
'svnlook changed --revision %REV% %REPOS%'
) DO (
SET POST=%%b
)

C:\wget_for_win\wget ^
    --header="Content-Type:text/plain;charset=UTF-8" ^
    --post-data="%POST%" ^
    --output-document="-" ^
    --timeout=2 ^
    http://localhost:8080/jenkins/subversion/%UUID%/notifyCommit?rev=%REV%

提交后挂钩现在正在工作。

  • 对于那些想要 Windows 版本的 wget 的人，请使用WGET for Windows。
于 2013-12-10T07:14:16.190 回答