46

如何Class从该类的实例中获取 actionscript 类的实例？

在 Python 中，这将是x.__class__; 在 Java 中，x.getClass();.

我知道存在某些可怕的黑客来做到这一点，但我正在寻找一种内置的语言工具，或者至少是一个建立在可靠东西上的库例程。

4

3 回答 3

69

您可以通过基 Object 类的“构造函数”属性来获取它。IE：

var myClass:Class = Object(myObj).constructor;
于 2008-10-15T08:19:41.077 回答
14

你有什么理由不能这样做？

var s:Sprite = new flash.display.Sprite();

var className:String = flash.utils.getQualifiedClassName( s );
var myClass:Class = flash.utils.getDefinitionByName( className ) as Class;

trace(className ); // flash.display::Sprite
trace(myClass); // [class Sprite]

var s2 = new myClass();
trace(s2); // [object Sprite]

我不知道避免通过字符串往返的方法，但它应该工作得很好。

于 2008-10-15T08:18:02.377 回答
14

公认的（也是目前最流行的答案）有一些缺陷。答案适用于这个特定的用例，但评论已将答案扩展为看似通用的解决方案。

但在某些情况下，它不是一个类型安全的解决方案，并且它不能处理所有可能的对象。不支持 XML 的想法在这里和其他地方已经得到了很好的解决，但类型安全的想法却没有。

所做的假设是它是程序员创建的类对象。这是我设置的一些测试（这是在严格模式下，但是是本地测试）。注意int测试结果：

var sprite:Sprite = new Sprite();
var xml:XML = new XML();
var testInt:int = 2;
var testClass:TestClass = new TestClass();
var testAnon:Object = {};

trace("classname 1 = " + getQualifiedClassName(sprite));
trace("myclass 1 = " + getDefinitionByName(getQualifiedClassName(sprite)));
trace("constructor a 1 = " + Object(sprite).constructor);
trace("constructor a 1 = " + (Object(sprite).constructor as Class));
trace("constructor b 1 = " + sprite["constructor"]);
trace("constructor b 1 = " + (sprite["constructor"] as Class));
trace("...");
trace("classname 2 = " + getQualifiedClassName(xml));
trace("myclass 2 = " + getDefinitionByName(getQualifiedClassName(xml)));
trace("constructor a 2 = " + Object(xml).constructor);
trace("constructor a 2 = " + (Object(xml).constructor as Class));
trace("constructor b 2 = " + xml["constructor"]);
trace("constructor b 2 = " + (xml["constructor"] as Class));
trace("...");
trace("classname 3 = " + getQualifiedClassName(testInt));
trace("myclass 3 = " + getDefinitionByName(getQualifiedClassName(testInt)));
trace("constructor a 3 = " + Object(testInt).constructor);
trace("constructor a 3 = " + (Object(testInt).constructor as Class));
trace("constructor b 3 = " + testInt["constructor"]);
trace("constructor b 3 = " + (testInt["constructor"] as Class));
trace("...");
trace("classname 4 = " + getQualifiedClassName(testClass));
trace("myclass 4 = " + getDefinitionByName(getQualifiedClassName(testClass)));
trace("constructor a 4 = " + Object(testClass).constructor);
trace("constructor a 4 = " + (Object(testClass).constructor as Class));
trace("constructor b 4 = " + testClass["constructor"]);
trace("constructor b 4 = " + (testClass["constructor"] as Class));
trace("...");
trace("classname 5 = " + getQualifiedClassName(testAnon));
trace("myclass 5 = " + getDefinitionByName(getQualifiedClassName(testAnon)));
trace("constructor a 5 = " + Object(testAnon).constructor);
trace("constructor a 5 = " + (Object(testAnon).constructor as Class));
trace("constructor b 5 = " + testAnon["constructor"]);
trace("constructor b 5 = " + (testAnon["constructor"] as Class));
trace("...");

定义TestClass为：

package
{
    public class TestClass
    {
    }
}

结果：

classname 1 = flash.display::Sprite
myclass 1 = [class Sprite]
constructor a 1 = [class Sprite]
constructor a 1 = [class Sprite]
constructor b 1 = [class Sprite]
constructor b 1 = [class Sprite]
...
classname 2 = XML
myclass 2 = [class XML]
constructor a 2 = 
constructor a 2 = null
constructor b 2 = 
constructor b 2 = null
...
classname 3 = int
myclass 3 = [class int]
constructor a 3 = [class Number]
constructor a 3 = [class Number]
constructor b 3 = [class Number]
constructor b 3 = [class Number]
...
classname 4 = src::TestClass
myclass 4 = [class TestClass]
constructor a 4 = [class TestClass]
constructor a 4 = [class TestClass]
constructor b 4 = [class TestClass]
constructor b 4 = [class TestClass]
...
classname 5 = Object
myclass 5 = [class Object]
constructor a 5 = [class Object]
constructor a 5 = [class Object]
constructor b 5 = [class Object]
constructor b 5 = [class Object]
...

除了当前的任何测试之外，还有相当充分的理由使用getDefinitionByName这些constructor方法。该getDefinitionByName方法允许：

  • Adobe 为（当前和未来）有问题的领域开发内部解决方案
  • 您不必为将来的 Adob​​e 开发更改代码
  • 您不必开发两个（或更多）单独的动态实例化方法。

现在可能会变慢，但将来 Adob​​e 方面可能会进行改进以解决速度问题。

（例如，以前uintfor-loops 比 慢int很多，所以设置了很多转换代码来使用 fast int。这是一个相当简单的问题要解决，所以 Adob​​e 修复了它，现在有很多代码跳过了一些不必要的障碍来实现过时的目标。）

由于该getDefinitionByName方法在所有情况下都能正常工作，因此应使用该方法开发代码，然后努力让 Adob​​e 修复速度问题。

于 2012-02-05T20:35:47.920 回答