2

我有以下 XSLT 样式表（简化）：

<?xml version="1.0" encoding="utf-8"?>
<xsl:stylesheet version="1.0"
xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
xmlns:exsl="http://exslt.org/common"
exclude-result-prefixes="exsl">

<xsl:output method="xml" version="1.0" encoding="UTF-8" indent="yes"/>

<xsl:variable name="categories">
    <category name="one"/>
    <category name="two"/>
    <category name="three"/>
</xsl:variable>

<xsl:template match="/">
<result>

<xsl:for-each select="exsl:node-set($categories)/category">
<xsl:element name="{@name}">

<!-- THIS IS THE PROBLEMATIC PART -->
    <xsl:for-each select="/input/object">
        <item>
            <xsl:value-of select="."/>
        </item>
    </xsl:for-each>

</xsl:element>
</xsl:for-each>
</result>
</xsl:template>
</xsl:stylesheet>

这指的是以下源 XML 文档（也已简化）：

<?xml version="1.0" encoding="utf-8"?>
<input>
    <object category="one">a</object>
    <object category="one">b</object>
    <object category="two">c</object>
    <object category="one">d</object>
    <object category="three">e</object>
</input>

对源文档的引用不会产生任何结果；输出只是空元素，每个类别一个：

<?xml version="1.0" encoding="UTF-8"?>
<result>
  <one/>
  <two/>
  <three/>
</result>

如何用源文档中的项目“填充”元素？

澄清一下，这背后的“真正”问题已经通过不同的方法解决了。我只是想了解为什么这种方法不起作用。

4

1 回答 1

5

在xsl:for-eachXPaths 的上下文中被解释为选定的“文档”，即/引用node-set($categories). 您可以通过尝试以下代码来亲自查看：

<xsl:template match="/">
  <xsl:variable name="root" select="/"/>
  <result>

  <xsl:for-each select="exsl:node-set($categories)/category">
    <xsl:element name="{@name}">

    <xsl:for-each select="$root/input/object">
        <item>
            <xsl:value-of select="."/>
        </item>
    </xsl:for-each>

    </xsl:element>
  </xsl:for-each>
  </result>
</xsl:template>

它使用该变量root将对模板选择的文档的访问传递给内部xsl:for-each循环。（注意：变量也可以放在模板之外。）

/您可以通过替换原始代码中的select="/input/object"by 来仔细检查是否实际使用了节点集。select="/category"您将在元素中获得空项目（每个类别一个）。

于 2013-11-21T07:31:46.197 回答