3

我正在尝试定义一些 emacs 字体来进行一些自定义突出显示。当我单独定义它们时，这似乎有效：

(defface my-r-face `((t (:foreground "red")))  "Red highlight")
(defvar m-r-face 'my-r-face "Red.")
(defface my-g-face `((t (:foreground "green")))  "Green highlight")
(defvar m-g-face 'my-g-face "Green.")
(defface my-b-face `((t (:foreground "#0088ff")))  "Blue highlight")
(defvar m-b-face 'my-b-face "Blue.")
....etc

但是我有几十个，我想从某种颜色表中一次性定义它们：

(setq ctable '(("red" "r")
           ("orange" "o")
           ("yellow" "y")
           ("#88ff00" "gy")
           ("green" "g")
           ("#00ff88" "gc")
           ("cyan" "c")
           ("#0088ff" "bc")
           ("blue" "b")
           ("purple" "bm")
           ("magenta" "m")
           ("#ff0088" "rm")
           ("grey" "lg")
           ("white" "w") ))

我的困难在于为每个面组装符号名称，即将“my-”和“-face”连接到表格条目的任一侧。我发现（实习生）可以从字符串中创建一个新符号，但是这个符号对于（defface）来说是不可接受的，因为我正在做的似乎等同于（defface'my-r-face ...，并且 defface 不喜欢引用的符号，并且期望 (defface my-r-face .. 代替。我的尝试如下：

(dolist (tpl ctable)
  (defvar (intern (concat "my-" (nth 1 tpl) "-face"))
    (quote (intern (concat "my-" (nth 1 tpl) "-face"))) "colour")
  (defface (intern (concat "my-" (nth 1 tpl) "-face"))
    `((t (:foreground ,(car tpl)))) "Highlight" :group 'fortran)
)

运行此结果

Lisp error: (wrong-type-argument symbolp (intern (concat "fegs-" (nth 1 tpl) "-face")))
  (defvar (intern (concat "fegs-" ... "-face")) (quote (intern ...)) "colour")

任何人都可以阐明我做错了什么，或者我是否完全在错误的树上吠叫并且有更好的方法来做到这一点？

谢谢。

4

3 回答 3

3

你可以避免eval：

(defconst my-ctable '(...))

(defmacro my-init-cfaces ()
  `(progn
    ,@(mapcar (lambda (tpl)
               `(defface ,(intern (format "my-%s-face" (nth 1 tpl)))
                  '((t :foreground ,(car tpl)))
                  ,(format "Face for color %s." (car tpl))
                  :group 'fortran))
              my-ctable)))

(my-init-cfaces)
于 2013-11-15T13:39:46.410 回答
1

defvar 是一种特殊形式， defface 是一个宏（所以参数被传递而不求值）。您是否尝试过使用以下内容

(eval `(defface ,(intern "foo") '((t (:foreground "red"))) "Highlight" :group 'fortran))

(eval `(defvar ,(intern "bar")))
于 2013-11-15T12:06:54.367 回答
0

最终工作的完整代码如下：

(setq ctable '(("red" "r")
           ("orange" "o")
           ("yellow" "y")
           ("#88ff00" "gy")
           ("green" "g")
           ("#00ff88" "gc")
           ("cyan" "c")
           ("#0088ff" "bc")
           ("blue" "b")
           ("purple" "bm")
           ("magenta" "m")
           ("#ff0088" "rm")
           ("grey" "lg")
           ("white" "w") ))

(dolist (tpl ctable)
  (let ((fname (concat "fegs-" (nth 1 tpl) "-face")))
    (eval `(defface ,(intern fname) '((t (:foreground ,(car tpl)))) "Highlight" :group 'fortran))
    (eval `(defvar ,(intern fname) ',(intern fname)))
  )
)

我的 defvar 行略有不同，因为这允许面部被其他地方的突出显示代码作为全局变量拾取。

于 2013-11-15T12:43:49.770 回答