4

我正在尝试创建一个模型，其中海龟随机行走（但有向前移动的趋势），直到它们降落在代表诱饵物体的黄色斑块上。

当一只乌龟落在其中一个黄色斑块上时，我希望它停在那个斑块上并在那里停留 15 滴，同时它“调查”诱饵。

在 15 个滴答声过去后，我希望海龟像往常一样继续移动，直到它们遇到另一个黄色斑块。

我试图在 netlogo 建模共享中修改此停放卡模型的部分内容，但无法真正理解它（我是 netlogo 的新手） http://modelingcommons.org/browse/one_model/3205#model_tabs_browse_procedures

我也尝试过实现一个倒数计时器，如该线程中所述 如何在 NetLogo 中创建倒数计时器？

但是，当我尝试运行模拟时，我收到一个运行时错误“只有观察者可以询问所有海龟的集合”。谁能告诉我哪里出错了？大概好几个地方！谢谢。

这是导致运行时错误的代码：

turtles-own [count-down]

to setup 
clear-all
ask patches with [count neighbors != 8]
[set pcolor blue]                   

create-turtles 20
ask turtles 
 [setxy random-xcor random-ycor 
 pen-down]   

ask n-of 20 patches
[ set pcolor yellow ]                   

reset-ticks
end

to go
 move-turtles
 tick
 if ticks >= 720 [stop]

 end


to move-turtles
ask turtles
  [ ifelse pcolor != yellow
  [continue]
  [stay]
  ]
 end

 to continue
ask turtles   
[rt -90 + random 181]
ask turtles
[ifelse [pcolor] of patch-ahead 1 = blue [ lt random-float 360 ]   
[fd 1]  
]
end

to stay
ask turtles 
[
setup-timer
decrement-timer
if timer-expired? [continue]
]
end

to setup-timer
set count-down 15
end

to decrement-timer
set count-down count-down - 1
end

to-report timer-expired?
report ( count-down <= 0 )
end
4

2 回答 2

4

这只是一个例子，他们应该在黄色区域停留多少个刻度？我假设有 15 个滴答声，我也要求海龟在它们的标签上打印它们的滴答声编号，如果它跑得太快，您可能会错过它们的停留，因此请调整模型的运行速度，以查看它们何时停留以及何时移动。你可以有不同的方法来继续，在这个方法中他们只是向前移动了 1 个补丁。

turtles-own [count-down]

to setup 
  clear-all
  ask patches with [count neighbors != 8]
  [set pcolor blue]                   

  create-turtles 20
  ask turtles 
  [setxy random-xcor random-ycor 
    pen-down
    set count-down 15
  ]   

  ask n-of 20 patches
  [ set pcolor yellow ]                   

  reset-ticks
end

to go
  move-turtles
  tick
  if ticks >= 720 [stop]

end


to move-turtles
  ask turtles
  [ ifelse pcolor != yellow
    [continue]
    [stay]
  ]
end

To continue   
  rt random 10
  fd 1 
end


to stay   
  set count-down count-down - 1   ;decrement-timer
  set label count-down    
  if count-down = 0 
    [
      Continue
      set label ""
      reset-count-down
    ]    

end

to reset-count-down   
  set count-down 15 
end
于 2013-11-15T10:17:51.843 回答
2

要回答有关“只有观察者可以询问所有海龟的集合”的部分，如果您这样做，则会出现该错误消息：

ask turtles [
  ask turtles [
    do-something
  ]
]

这在 NetLogo 中是不允许的，因为它几乎总是意外而不是故意的。你可能只是想让每只乌龟“做点什么”一次；您可能并不是说每只乌龟都要为每对可能的两只乌龟“做点什么”。

让所有海龟询问所有海龟是否跨程序拆分，这一点不太明显。例如，如果你写：

to go
  ask turtles [ my-procedure ]
end

to my-procedure
  ask turtles [ do-something ]
end

出于同样的原因，它仍然是错误的，但仅仅看一眼就不太容易看出这一点。

您的代码遵循后一种模式。你有：

to move-turtles
  ask turtles [
    ...
    continue
    ...
  ]
end

to continue
  ask turtles [
    rt -90
    ...
  ]
end

我不认为你想ask turtles在continue程序中做。既然你在里面调用了这个过程ask turtles，它就已经是一个乌龟过程了。我建议把它写成：

to continue  ;; turtle procedure
  rt -90
  ...
end

该评论提醒您，它旨在由海龟运行。（我们在模型库中的所有模型中都遵循这种风格。）

于 2013-11-15T13:43:31.497 回答