visual-studio-2010 - 列表框上的鼠标移动句柄

Question

我有一个 ListBox，我想在其上处理 mousemove 事件；出于这个原因，我使用以下代码

Private Sub AreaLB_MouseMove(sender As Object, e As System.Windows.Forms.MouseEventArgs) Handles AreaLB.MouseMove
        Dim ListMousePosition As Point = AreaLB.PointToClient(Me.MousePosition)
        Dim itemIndex As Integer = AreaLB.IndexFromPoint(ListMousePosition)
        Dim AreaToolTip As ToolTip = ToolTip1
        Dim myLB As ListBox = AreaLB
        AreaToolTip.Active = True
        Dim g As Graphics = AreaLB.CreateGraphics()
        If itemIndex > -1 Then
            Dim s As String = myLB.Items(itemIndex)
            If g.MeasureString(s, myLB.Font).Width > myLB.ClientRectangle.Width Then
                AreaToolTip.SetToolTip(myLB, s)
            Else
                AreaToolTip.SetToolTip(myLB, "")
            End If
            g.Dispose()
        End If
    End Sub

我的问题是......当我不移动鼠标时，这个过程总是在
g.MeasureString(s, myLB.Font).Width > myLB.ClientRectangle.Width
为什么会发生以及如何避免它时运行。

Answer 1

您可以做的只是设置 ToolTip 如果它还不是您想要的值：

Private Sub AreaLB_MouseMove(sender As Object, e As System.Windows.Forms.MouseEventArgs) Handles AreaLB.MouseMove
    ToolTip1.Active = True
    Dim itemIndex As Integer = AreaLB.IndexFromPoint(e.X, e.Y)
    If itemIndex > -1 Then
        Using g As Graphics = AreaLB.CreateGraphics()
            Dim s As String = AreaLB.Items(itemIndex)
            If g.MeasureString(s, AreaLB.Font).Width > AreaLB.ClientRectangle.Width Then
                If ToolTip1.GetToolTip(AreaLB) <> s Then
                    ToolTip1.Show(s, AreaLB)
                End If
            Else
                ToolTip1.Show("", AreaLB)
            End If
        End Using
    End If
End Sub