2

我正在尝试实现一个递归函数，它接收一棵树并列出它拥有的所有路径。

我当前的实现不起作用：

let rec pathToList tree acc =
    match tree with
    | Leaf -> acc
    | Node(leftTree, x, rightTree) ->
        let newPath = x::acc
        pathToList leftTree newPath :: (pathToList rightTree newPath)

...因为pathToList leftTree newPath不返回元素而是列表，因此错误。

这可以通过 set 来解决，例如：

let rec pathToList2 t acc =
    match t with
    | Leaf -> Set.singleton acc
    | Node(leftTree, x, rightTree) ->
        let newPath = x::acc
        Set.union (pathToList2 leftTree newPath) (pathToList2 rightTree newPath)

现在，我有点坚持使用列表（以前）而不是设置（后来）来解决这个问题，关于如何使用尾递归解决这个问题的任何建议？

4

1 回答 1

2

为了不求助于解决这个问题@（这是低效的，因为它在第一个列表的长度上是线性的），您将需要两个累加器：一个用于向下到父节点的路径（因此您可以构建到当前的路径节点），一个用于迄今为止您找到的所有路径（因此您可以添加找到的路径）。

let rec pathToListRec tree pathToParent pathsFound =
    match tree with
    | Leaf -> pathsFound
    | Node (left, x, right) ->
        let pathToHere = x :: pathToParent

        // Add the paths to nodes in the right subtree
        let pathsFound' = pathToListRec right pathToHere pathsFound

        // Add the path to the current node
        let pathsFound'' = pathToHere :: pathsFound'

        // Add the paths to nodes in the left subtree, and return
        pathToListRec left pathToHere pathsFound''

let pathToList1 tree = pathToListRec tree [] []

就尾递归而言，您可以看到上述函数中的两个递归调用之一位于尾部位置。但是，仍然有一个非尾部位置的调用。

这是树处理函数的经验法则：你不能轻易地使它们完全尾递归。原因很简单：如果你天真地这样做，至少两个递归中的一个（向下到左子树或到右子树）必然处于非尾位置。唯一的方法是使用列表模拟调用堆栈。这意味着您将具有与非尾递归版本相同的运行时复杂性，除非您使用的是列表而不是系统提供的调用堆栈，因此它可能会更慢。

无论如何，这就是它的样子：

let rec pathToListRec stack acc =
    match stack with
    | [] -> acc
    | (pathToParent, tree) :: restStack ->
        match tree with
        | Leaf -> pathToListRec restStack acc
        | Node (left, x, right) ->
            let pathToHere = x :: pathToParent

            // Push both subtrees to the stack
            let newStack = (pathToHere, left) :: (pathToHere, right) :: restStack

            // Add the current path to the result, and keep processing the stack
            pathToListRec newStack (pathToHere :: acc)

// The initial stack just contains the initial tree
let pathToList2 tree = pathToListRec [[], tree] []

代码看起来并不算太糟糕，但它所花费的时间是非尾递归代码的两倍多，而且分配的次数也更多，因为我们使用列表来完成堆栈的工作！

> #time;;
--> Timing now on
> for i = 0 to 100000000 do ignore (pathToList1 t);;
Real: 00:00:09.002, CPU: 00:00:09.016, GC gen0: 3815, gen1: 1, gen2: 0
val it : unit = ()
> for i = 0 to 100000000 do ignore (pathToList2 t);;
Real: 00:00:21.882, CPU: 00:00:21.871, GC gen0: 12208, gen1: 3, gen2: 1
val it : unit = ()

结论：规则“让它尾递归它会更快！” 当需要进行多次递归调用时，不应遵循极端，因为它需要以一种使其更慢的方式更改代码。

于 2013-11-10T20:20:12.183 回答