2

我正在尝试了解身份模板的功能。

  <xsl:template match='@* | node()'>
  <xsl:apply-templates select='@* | node()'/>
  </xsl:template>

上面的模板如果出现在我们的 XSL 文档的开头，我们称之为身份模板，它的功能是调用所有模板，即通过匹配 @* 和匹配中的 node() 下的所有内容。然后它转到第二行 apply-templates，它递归地选择所有模板/节点。如果我在这里错了，请纠正我。

我的问题是，如果我们把这个模板放在 XSLT 的中间，但不是在开始，我们不想要所有匹配的动作，而只想要存储在变量中的某个消息，比如 

  <xsl:template match='$variable holding entire soap envelope'>
  <xsl:apply-templates select='@* | node()'/>
  </xsl:template>

我们是否仍将其称为身份模板，并且在第一次操作时它仍会像身份模板一样处理吗？

对不起，如果我的问题不清楚。

感谢帮助。

4

2 回答 2

2

不，覆盖身份转换的模板本身不会被视为身份转换。

使用身份转换模板的方法是让它默认复制从输入 XML 到输出 XML 的所有内容，但在需要时使用更具体的模式覆盖身份转换。match

例如，考虑这个 SOAP 消息：

<env:Envelope xmlns:env="http://www.w3.org/2003/05/soap-envelope">
  <env:Header>
    <n:alertcontrol xmlns:n="http://example.org/alertcontrol">
      <n:priority>1</n:priority>
      <n:expires>2001-06-22T14:00:00-05:00</n:expires>
    </n:alertcontrol>
  </env:Header>
  <env:Body>
    <m:alert xmlns:m="http://example.org/alert">
      <m:msg>Pick up Mary at school at 2pm</m:msg>
    </m:alert>
  </env:Body>
</env:Envelope>

如果我们想将此消息转换为几乎相同但可能具有不同m:msg内容的另一个消息，我们可以使用带有覆盖m:msg的身份转换：

<xsl:stylesheet version="1.0"
                xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
                xmlns:m="http://example.org/alert">
  <xsl:output omit-xml-declaration="yes" indent="yes"/>
  <xsl:strip-space elements="*"/>

  <xsl:template match="node()|@*">
    <xsl:copy>
      <xsl:apply-templates select="node()|@*"/>
    </xsl:copy>
  </xsl:template>

  <xsl:template match="m:msg">
    <xsl:copy>***Pick up Mary at school at 1pm, not 2pm.***</xsl:copy>
  </xsl:template>

</xsl:stylesheet>

将上述 XSLT 应用于输入 SOAP 消息会生成相同的 SOAP 消息，但具有新的m:msg元素内容：

<env:Envelope xmlns:env="http://www.w3.org/2003/05/soap-envelope">
   <env:Header>
      <n:alertcontrol xmlns:n="http://example.org/alertcontrol">
         <n:priority>1</n:priority>
         <n:expires>2001-06-22T14:00:00-05:00</n:expires>
      </n:alertcontrol>
   </env:Header>
   <env:Body>
      <m:alert xmlns:m="http://example.org/alert">
         <m:msg>***Pick up Mary at school at 1pm, not 2pm.***</m:msg>
      </m:alert>
   </env:Body>
</env:Envelope>
于 2013-11-08T14:44:58.480 回答
2

身份转换模板复制每个节点，因此看起来像

  <xsl:template match='@* | node()'>
    <xsl:copy>
      <xsl:apply-templates select='@* | node()'/>
    </xsl:copy>
  </xsl:template>

至于以变量引用开头的匹配模式match='$variable'，我认为这在 XSLT 1.0 中是不允许的。

于 2013-11-08T14:06:55.167 回答