1

所以我正在为一些人创建一个文档，其中每个组（其中三个）被分配了一种字体颜色，以便他们输入到文档中。我编写了一个 VBA 脚本，其中包含所有相关人员的列表，并且可以识别登录到计算机的人员和他们所在的组。但是，我无法让字体颜色自行设置。我记录了一个 VBA 脚本，我在其中设置了字体颜色以查看 Word 是如何做到的，但是Selection.Font.Color = wdColorRed当我将其添加到我的 VBA 脚本时，生成的代码实际上不会改变所选的字体颜色。这是我正在使用的代码示例：

Private Sub Document_Open()

Dim Users As New Scripting.Dictionary
Dim UserID As String
Dim category As String

UserID = GetUserName 'Currently using the example at
                     'http://support.microsoft.com/kb/161394 as a function

'---Add Members of Group 1---
Users.Add "person1", "group1"
Users.Add "person2", "group1"

'---Add Members of Group 2---
Users.Add "person3", "group2"
Users.Add "person4", "group2"
Users.Add "person5", "group2"

'---Add Members of Group 3---
Users.Add "person6", "group3"
Users.Add "person7", "group3"

For Each user In Users.Keys
    If user = UserID Then
        If Users.Item(user) = "group1" Then
            Selection.Font.Color = wdColorRed
        ElseIf Users.Item(user) = "group2" Then
            Selection.Font.Color = wdColorGreen
        ElseIf Users.Item(user) = "group3" Then
            Selection.Font.Color = wdColorBlue
        Else
            Selection.Font.Color = wdColorBlack
        End If
    End If
Next

End Sub
4

2 回答 2

0

AFAIK，您不能为特定用户设置默认字体颜色。即使您设法将其设置为蓝色，然后导航到一个红色的句子，如果您输入任何内容，您也不会看到蓝色文本而是红色文本。因为光标所在的位置将选择用于为该句子着色的原始颜色。

要为用户设置特定颜色，您要么必须要么

  1. Identify a range and set the color for it. 但是就像我上面提到的那样，如果用户导航到不同的范围，那么新的颜色设置将不会在那里应用。

  2. Set it for the entire document. 如果您为整个文档设置它，那么整个文档的颜色将会改变，我相信这不是您想要的。

于 2013-11-07T17:43:05.440 回答
0

可能的解决方法基于 Application.WindowSelectionChange Event. 因此，您需要保留以下步骤：

1.创建类模块
2.命名您的类模块 3.App
将以下代码添加到App Class Module：

    Public WithEvents WRD As Application

    Private Sub WRD_WindowSelectionChange(ByVal Sel As Selection)
        'here you should place solution from your Document_Open sub
        'which defines color based on user name or...
        'you could place it somewhere else but pass color value 
        'here as a parameter

        'for test I just assumed that color should be blue
        Sel.Font.Color = wdColorBlue
    End Sub

4.在标准模块中添加公共变量：

    Public tmpApp As New App

5.在标准模块中创建Sub，或者添加代码到你的Document_Open Event，这将初始化我们的类：

Sub Document_Open_new()

    Set tmpApp.WRD = Application

    'we need to change selection once to trigger full
    'scope of solution
    'if we omit the code below new color will not work
    'if user add new text at the beginning of the document
    'right after it was opened
    Dim tmpSel As Range
    Set tmpSel = Selection.Range
    ActiveDocument.Bookmarks("\EndOfDoc").Select
    tmpSel.Select
End Sub

6.运行上述子程序一次或打开文档，如果代码已添加到Document_open event.

---编辑---（在下面@Sid的一些评论之后）

使用建议的解决方案存在一些不便。但是，大多数都可以通过If statements在里面添加一些来解决WindowSelectionChange event。检查Sel range参数的位置、周围的文本和其他可以精确地决定是否应该应用新颜色。

于 2013-11-07T20:59:08.387 回答