3

下午好，

我有一个小的 Perl 脚本，它基本上模拟tail -f了 Minecraft server.log 上的功能。该脚本检查某些字符串并以各种方式执行。

脚本的简化版本如下：

#!/usr/bin/perl

use 5.010;
use warnings;
use strict;

my $log = "PATH TO LOG";
my $curpos;

open(my $LOGFILE, $log) or die "Cannot open log file";

# SEEK TO EOF
seek($LOGFILE, 0, 2);

for (;;){
        my $line = undef;

        seek($LOGFILE,0,1);  ### clear OF condition
        for($curpos = tell($LOGFILE); <$LOGFILE>; $curpos = tell($LOGFILE)){
                $line = "$_ \n";


                if($line =~ /test string/i){
                        say "Found test string!";
                }
        }

        sleep 1;
        seek($LOGFILE,$curpos,0); ### Setting cursor at the EOF
}

当我启动测试服务器时，一切似乎都运行良好。在生产中，server.log 文件被轮换。当日志轮换时，脚本会保留原始文件，而不是替换它的文件。即 server.log 正在被监控，server.log 被移动并压缩到 logs/date_x.log.gz，server.log 现在是一个新文件。

如何调整我的脚本以监视文件名“server.log”，而不是当前称为“server.log”的文件？

4

2 回答 2

5

您是否考虑过仅将tail -F其用作脚本的输入：

tail -F server.log 2>/dev/null | perl -nE 'say if /match/'

这将监视命名文件，将每一行传递给 STDIN 上的脚本。它将仅正确跟踪 server.log，如下所示：

echo 'match' >server.log

（由脚本匹配）

mv server.log server.log.old
echo 'match' >server.log

（也匹配）

您可以tail -F使用以下命令在 Perl 中将其作为文件打开：

open(my $fh, '-|', 'tail -F server.log 2>/dev/null') or die "$!\n";
于 2013-11-07T12:51:56.493 回答
2

您可以使用 . 检查文件名和文件句柄的inode 编号stat()。如果它们不同，则轮换日志文件并应重新打开文件以供阅读。

$readline是迭代器（由 获得get_readline($file_name)），它透明地处理这些变化，并做“正确的事情”。

use strict;
use warnings;

sub get_readline {
  my ($fname) = @_;
  my $fh;

  return sub {
    my ($i1, $i2) = map { $_ ? (stat $_)[1] : 0 } $fh, $fname;

    if ($i1 != $i2) {
      undef $fh;
      open $fh, "<", $fname or return;
    }
    # reset handle to current position
    seek($fh, 0, 1) or die $!;
    return wantarray ?  <$fh> : scalar <$fh>;
  };
}

`seq 11 > log_file`;
my $readline = get_readline("log_file");

print "[regular reading]\n";
print $readline->();
print "[any new content?]\n";
print $readline->();

`rm log_file; seq 11 > log_file`;
print "[reading after log rotate]\n";
print $readline->();

输出

[regular reading]
1
2
3
4
5
6
7
8
9
10
11
[any new content?]
[reading after log rotate]
1
2
3
4
5
6
7
8
9
10
11
于 2013-11-07T14:03:24.630 回答