0

我有一个 Windows 批处理脚本每 10 分钟调用另一个批处理。我使用 For 循环调用批处理，然后等待 10 分钟。

@ECHO OFF
echo %date:~0,10% %time% Running Post To GIM II ...
FOR %%a IN (1,2,3,4,5) DO (
echo %date:~0,10% %time% Starting Post To GIM II ...
CALL D:\Appshares\Autosys\scripts\Sophis\_commonJobWrapper.bat    D:\sophis\Client\UBS_PostToGIMII.exe
echo %date:~0,10% %time% Ending Post To GIM II ...
PING -n 600 127.0.0.1 >NUL 2>&1 
)

但是，内部批处理接受另一个 .exe 作为参数。但是内部批处理只执行一次然后退出。内部批处理代码是这样的。谁能告诉为什么循环在 1 次运行后总是退出？

@echo off

REM parameter 1 is the program to be called, parameter 2 onwards are additional optional parameters
REM -- Record Time
echo --- JobWrapper Start : %date% %time% ---

REM -- Set starting folder to where application was called from
  cd /d %~dp0
REM -- Set Secure varibales via a securly permissioned file
  if exist _CommonBeginSecure.BAT (call _CommonBeginSecure.BAT)
REM -- Debug mode, start message
  if "%_senddebug%" NEQ "" cscript.exe /NOLOGO %_sendmail% "%_applic% (%_envname%): Autosys job started - %~nx1" "Logfile: %~n1.out" %_senddebug% %_sendfrom%
REM -- Call program passing thru any parameters (currently maximum of 9)
  echo Calling: %1
  call %1 %2 %3 %4 %5 %6 %7 %8 %9
REM -- Error Handling
if %errorlevel% NEQ 0 goto error
goto end

:error

REM -- Send Failed Message
if "%_sendto%" NEQ "" cscript.exe /NOLOGO %_sendmail% "%_applic% (%_envname%): Autosys job FAILED - %~nx1" "Logfile: %~n1.out  (Errorlevel: %2)" %_sendto% %_sendfrom%
exit 1

:end
REM - Debug mode, end message
if "%_senddebug%" NEQ "" cscript.exe /NOLOGO %_sendmail% "%_applic% (%_envname%): Autosys job finished - %~nx1" "Logfile: %~n1.out" %_senddebug% %_sendfrom%
REM -- Record Time 
echo --- JobWrapper End : %date% %time% ---    
exit 0
rem - Notes:
rem %0 = Full name of this job 
rem %~dp0 = Actual path of this job
rem     %~nx0 = Filename of this job
rem     %~n0  = Filename of this job (excluding extension)
4

1 回答 1

1

你需要使用exit /b errorcode.

Exit命令，没有 /b 关闭 cmd 实例。使用 /b 关闭正在运行的批处理文件。

于 2013-11-06T15:37:43.033 回答