5

我需要将一些数据写入子文件句柄。文件句柄是在分叉之前在父级中创建的。这是因为我可以从父级的文件句柄中读取数据，因为 fork 保留文件句柄并锁定它们（如果有的话），在父级和子级之间共享。这是为了在 linux 和 windows 平台上共享父子节点的数据。我能够在 linux 中使用 IPC::Shareable 进行数据共享，但由于 windows 中的 semaphore.pm 不可用，这在 windows 中不起作用 [windos 不支持 semaphore.pm]，因此对于 windows，我尝试了 Win32::MMF 哪个正在使我的 perl 编译器崩溃。

因此，使用文件句柄方法，IO 写入不会发生在子进程中。请查看以下代码

use strict;
use warnings;

print "creating file\n"; 
open FH, ">testfile.txt" or die "cant open file: $!\n";
close FH;

my $pid = fork();

if ( $pid == 0 )
{
print "entering in to child and opening file for write\n";
open FH, ">>testfile.txt" or die "cant open file: $!\n";
print FH "dummy data\n";
print FH "dummy data\n";     
print "child sleeping for 5 sec before exiting\n";
sleep 50;
exit;

}
else
{
print "entering the parent process\n";   
open FH, "<testfile.txt" or die "cant open file: $!\n";
 print <FH>;
 print <FH>;


}
4

3 回答 3

2

感谢您帮助我解决这个问题。我昨天试图解决这个问题，发现一个关于 fork 的有趣的事情，同时将它与文件句柄一起用于在子级和父级之间共享数据，即我们可以使用以下代码解决问题，诀窍是在 fork 之前和内部打开文件句柄孩子只需写入文件句柄而不重新打开它。以下是修改后的代码。

use strict;
use warnings;
use Fcntl qw(:flock SEEK_END);

print "creating file handle\n"; 
open my $FH, ">testfile.txt" or die "cant open file: $!\n";
#close FH;

my $pid = fork();

if ( $pid == 0 )
{
 print "entering in to child and opening file for write\n";
 #open FH, ">>testfile.txt" or die "cant open file: $!\n";

   # Put a exclusive lock in the filehandle for dening access to any other process   during this child process run
   flock($FH, LOCK_EX) or die "Cannot lock testfile.txt - $!\n";

   # and, in case someone appended while we were waiting...
   seek($FH, 0, SEEK_END) or die "Cannot seek - $!\n";



   # write data to temp file with exclusive lock on it   
    print $FH "dummy data\n";
    print $FH "dummy data\n";

   # remove the lock once writing is done
    flock($FH, LOCK_UN) or die "Cannot unlock temp.txt - $!\n";

 print "child sleeping for 5 sec before exiting\n";
 sleep 2;
 exit;

}
else
{
 print "entering the parent process\n"; 
 #flock(FH, LOCK_UN) or die "Cannot unlock temp.txt - $!\n";

 sleep 3;    
 open $FH, "<testfile.txt" or die "cant open file: $!\n";

 while (<$FH>){
 print "$_\n";
 }
}
于 2013-11-07T06:47:41.677 回答
2

父进程应至少等待几分之一秒，以便让子进程有时间进行写入。

use strict;
use warnings;

print "creating file\n";
open my $FH, ">", "testfile.txt" or die "cant open file: $!\n";
close $FH;

my $pid = fork();

if ( $pid == 0 ) {
  print "entering in to child and opening file for write\n";
  open my $FH, ">>", "testfile.txt" or die "cant open file: $!\n";
  print $FH "dummy data\n";
  print $FH "dummy data\n";

  # print "child sleeping for 5 sec before exiting\n";
  # sleep 50;
  exit;
}
else {
  sleep 1;
  print "entering the parent process\n";
  open my $FH, "<", "testfile.txt" or die "cant open file: $!\n";
  print while <$FH>;
}

输出

creating file
entering in to child and opening file for write
entering the parent process
dummy data
dummy data
于 2013-11-06T11:44:22.933 回答
0

正如 mpapec 所说，您很容易受到竞争条件的影响，即父级在子级读取文件之前读取文件。如果您打算让子进程缓慢产生输出而父进程相对快速地处理它，那么父进程将经常读取文件末尾。您需要学习如何使用seek来重置文件结束标记并等待更多输入：

# parent process, after fork
sleep 1;         # give child time to create, write to file
open my $fh, '<', 'testfile.txt';
while (1) {

    my $line = <$fh>;
    if (defined($line)) {
        print $line;       # or  process($line)

        # another way (other than waitpid, see below) to see if the child is
        # finished is to use some convention between parent and child,
        # like having the child print "DONE!\n" as the last output it produces
        last if $line eq "DONE!\n";

    } else {

        # parent is starved for input. Is the child finished or is it just slow?
        use POSIX ':sys_wait_h';
        my $wpid = waitpid $pid, &WNOHANG;
        if ($wpid == $pid) {
            # child process has exited
            last;
        } else {
            # child is just slow. Clear the eof on $fh
            sleep 1;
            seek $fh, 0, 1;
        }
    }
}
close $fh;

您真正应该做的另一件事是在子进程中刷新您的输出。除非您非常快速地产生大量输出，否则输出将花费时间在缓冲区中并且父级无法访问：

if ( $pid == 0 ) {
  print "entering in to child and opening file for write\n";
  open my $fh, ">>", "testfile.txt" or die "cant open file: $!\n";

  $fh->autoflush(1);          # force OS to send output to disk right away

  print $fh "dummy data\n";
  print $fh "dummy data\n";

  print "child sleeping for 5 sec before exiting\n";
  sleep 5.0;
  # print $fh "DONE!\n";
  close $fh;
  exit;
}

进程间通信是非常棘手的事情，但也非常强大。保持练习。

于 2013-11-06T16:37:47.507 回答