0

我尝试用多个用户登录连接一个网站。

在连接站点时，Session-ID 被设置为 Web 浏览器中的 cookie。我试图通过生成一个对象数组来解决这个问题。

For i = 1 To Cnz
  Set oHttp(i) = CreateObject("Microsoft.XMLHTTP")
Next i

不幸的是，看起来所有 XMLHTTP 对象都共享相同的 Cookie 会话 ID。

有没有办法拥有独立的浏览器对象？或者手动设置cookies？或者使用不同的对象发送 http，获取结果，同时使用 cookie 管理 Session-ID。

4

1 回答 1

0

使用该MakeSessionRequest功能，您可以检索存储在 cookie 中的会话 ID，并在所有后续请求中使用

xmlHTTP.setRequestHeader "Cookie", "<key>=<value>"

Function MakeSessionRequest(method As String, url As String, data As String, _
 ByRef cookie As String, Optional ByRef updateCookie = False) As Byte()

  If Len(cookie) = 0 Then cookie = "dummy=dummy;"
  httpReferrer = Trim(url)
  postVars = Trim(data)

  Dim XMLHTTP As Object

    Set XMLHTTP = CreateObject("MSXML2.serverXMLHttp")
    XMLHTTP.Open method, Trim(url), False

    If UCase(method) = "POST" Then
      XMLHTTP.setRequestHeader "Content-Type", _
                       "application/x-www-form-urlencoded"
    End If
    XMLHTTP.setRequestHeader "Referer", httpReferrer 'in case the server cares
    XMLHTTP.setRequestHeader "Cookie", "to deal with XMLHTTP bug"
    XMLHTTP.setRequestHeader "Cookie", cookie
    XMLHTTP.send postVars

    'wait for response
    While XMLHTTP.readyState <> 4
      XMLHTTP.waitForResponse 1000
    Wend

    ' extract the cookie data from the response header
    If updateCookie Then
      cookie = ""
      strHeaders = XMLHTTP.getAllResponseHeaders()
      hArr = Split(strHeaders, "Set-Cookie: ")
      For kk = 1 To UBound(hArr)
          theCookie = Left(hArr(kk), InStr(hArr(kk), "path=/") - 2)
          cookie = cookie & " " & theCookie
      Next
    End If

    'return the response body
    MakeSessionRequest = XMLHTTP.responseBody
    Set XMLHTTP = Nothing
End Function
于 2013-11-04T04:19:16.360 回答