3

有时我希望能够做到以下几点：

“库xxx……”

其中 xxx 是我最后一次放入 kill-ring 的整数（通过在我的缓冲区中杀死一个数字）。

这是我想与宏一起使用的东西，所以我不能手动输入那个整数。

那么我怎样才能弹出杀死环并（解析并）将弹出的数字传递给“Cu”？

请注意，我想将它与多个功能一起使用，所以我真的希望它像 Cu 一样工作（但不是手动输入数字，而是希望从杀戮环中获取它）。

4

2 回答 2

4

这是一个粗略的尝试：

(defun prefix-argument-from-kill-ring ()
  "Set the numeric argument for the following command to the
number that was the previous kill."
  (interactive)
  (setq prefix-arg (list (string-to-number (current-kill 0)))))

一个更有原则的实现会检查 kill 的文本，如果它不是一个数字，就做一些明智的事情。

于 2013-11-01T17:45:36.927 回答
1

使用digit-argument作为模板，我写了这个，这似乎工作得很好：

(defun yank-universal-digits (arg)
  (interactive "P")
  (let* ((digits (current-kill 0))
         (digits (if (string-match "\\`0*\\([1-9][0-9]*\\)\\'" digits)
                     (match-string 1 digits)
                   (error "Current kill is not a positive integer")))
         (num (string-to-number digits)))
    (cond ((integerp arg)
           (setq prefix-arg (+ (* arg (expt 10 (length digits)))
                               (* num (if (< arg 0) -1 +1)))))
          ((eq arg '-)
           (setq prefix-arg (- num)))
          (t
           (setq prefix-arg num)))
    (setq universal-argument-num-events (length (this-command-keys)))
    (save&set-overriding-map universal-argument-map)))

(define-key universal-argument-map [?\C-y] 'yank-universal-digits)

将被杀死的数字安排在 minibuffer 中，就像您直接键入它们一样，这留作练习。

于 2013-11-01T18:24:18.257 回答