9

我正在尝试从数据库中读取数百万行并写入文本文件。

这是我的问题数据库转储到具有副作用的文本文件的延续

我现在的问题似乎是在程序完成之前不会发生日志记录。我没有懒惰地处理的另一个指标是，在程序完成之前根本不会写入文本文件。

根据 IRC 提示，看来我的问题可能与代码区域有关:result-set-fn并且默认为doall代码clojure.java.jdbc/query区域。

我试图用一个for函数替换它，但仍然发现内存消耗很高，因为它将整个结果集拉入内存。

我怎么能有一个:result-set-fn不把所有东西都拉进去的东西doall？如何在程序运行时逐步写入日志文件，而不是在-main执行完成后转储所有内容？ 

    (let [ 
          db-spec              local-postgres
          sql                  "select * from public.f_5500_sf "
          log-report-interval  1000
          fetch-size           100
          field-delim          "\t"                                                                  
          row-delim            "\n"                                                                  
          db-connection        (doto ( j/get-connection db-spec) (.setAutoCommit false)) 
          statement            (j/prepare-statement db-connection sql :fetch-size fetch-size ) 
          joiner               (fn [v] (str (join field-delim v ) row-delim ) )                      
          start                (System/currentTimeMillis)                                            
          rate-calc            (fn [r] (float (/ r (/ ( - (System/currentTimeMillis) start) 100))))  
          row-count            (atom 0)                                                              
          result-set-fn        (fn [rs] (lazy-seq rs))
          lazy-results         (rest (j/query db-connection [statement] :as-arrays? true :row-fn joiner :result-set-fn result-set-fn)) 
          ]; }}}
      (.setAutoCommit db-connection false)
      (info "Started dbdump session...")    
      (with-open [^java.io.Writer wrtr (io/writer "output.txt")]
        (info "Running query...")    
        (doseq [row lazy-results] 
          (.write wrtr row)
          ))  
        (info (format "Completed write with %d rows"   @row-count))
      )
4

3 回答 3

8

clojure.java.jdbc我通过放入[org.clojure/java.jdbc "0.3.0-beta1"]我的 project.clj 依赖项列表来获取最近的修复。这个增强/纠正了此处描述的:as-arrays? true功能。clojure.java.jdbc/query

我认为这有所帮助，但是我仍然可以覆盖:result-set-fnto vec。

通过将所有行逻辑放入:row-fn. 最初的 OutOfMemory 问题与遍历j/query结果集有关，而不是定义特定的:row-fn.

新（工作）代码如下：

(defn -main []
  (let [; {{{
        db-spec              local-postgres
        source-sql           "select * from public.f_5500 "
        log-report-interval  1000
        fetch-size           1000
        row-count            (atom 0)
        field-delim          "\u0001"   ; unlikely to be in source feed,
                                        ; although i should still check in
                                        ; replace-newline below (for when "\t"
                                        ; is used especially) 
        row-delim            "\n" ; unless fixed-width, target doesn't
                                  ; support non-printable chars for recDelim like 
        db-connection        (doto ( j/get-connection db-spec) (.setAutoCommit false))
        statement            (j/prepare-statement db-connection source-sql :fetch-size fetch-size :concurrency :read-only)
        start                (System/currentTimeMillis)
        rate-calc            (fn [r] (float (/ r (/ ( - (System/currentTimeMillis) start) 100))))
        replace-newline      (fn [s] (if (string? s) (clojure.string/replace  s #"\n" " ") s))
        row-fn               (fn [v] 
                               (swap! row-count inc)
                               (when (zero? (mod @row-count log-report-interval))
                                 (info (format "wrote %d rows" @row-count))
                                 (info (format "\trows/s %.2f"  (rate-calc @row-count)))
                                 (info (format "\tPercent Mem used %s "  (memory-percent-used))))
                               (str (join field-delim (doall (map #(replace-newline %) v))) row-delim ))
        ]; }}}
    (info "Started database table dump session...")
    (with-open [^java.io.Writer wrtr (io/writer "./sql/output.txt")]
      (j/query db-connection [statement] :as-arrays? true :row-fn 
               #(.write wrtr (row-fn %))))
    (info (format "\t\t\tCompleted with %d rows" @row-count))
    (info (format "\t\t\tCompleted in %s seconds" (float (/ (- (System/currentTimeMillis) start) 1000))))
    (info (format "\t\t\tAverage rows/s %.2f"  (rate-calc @row-count)))
    nil)
  )

我尝试的其他事情（成功有限）涉及音色记录和关闭标准输出；我想知道使用 REPL 是否会在显示回我的编辑器（vim 壁炉）之前缓存结果，我不确定这是否占用了大量内存。

此外，我使用 (.freeMemory (java.lang.Runtime/getRuntime)). 我对 VisualVM 不太熟悉，也不太清楚我的问题出在哪里。

我对它现在的工作方式感到满意，感谢大家的帮助。

于 2013-11-06T05:27:31.470 回答
4

您可以使用prepare-statement该:fetch-size选项。否则，尽管结果以惰性序列传递，但查询本身是急切的。

prepare-statement需要一个连接对象，因此您需要显式创建一个。以下是您的使用情况的示例：

(let [db-spec    local-postgres
      sql        "select * from big_table limit 500000 "
      fetch-size 10000 ;; or whatever's appropriate
      cnxn       (doto (j/get-connection db-spec)
                   (.setAutoCommit false))
      stmt       (j/prepare-statement cnxn sql :fetch-size fetch-size)
      results    (rest (j/query cnxn [stmt]))]
  ;; ...
  )

另外的选择

由于问题似乎与query，请尝试with-query-results。它被认为已弃用，但仍然存在并且有效。这是一个示例用法：

(let [db-spec    local-postgres
      sql        "select * from big_table limit 500000 "
      fetch-size 100 ;; or whatever's appropriate
      cnxn       (doto (j/get-connection db-spec)
                   (.setAutoCommit false))
      stmt       (j/prepare-statement cnxn sql :fetch-size fetch-size)]
  (j/with-query-results results [stmt] ;; binds the results to `results`
    (doseq [row results]
      ;;
      )))
于 2013-11-01T21:33:10.163 回答
2

我找到了一个更好的解决方案：您需要在事务中声明一个游标并从中获取大块数据。例子：

  (db/with-tx
    (db/execute! "declare cur cursor for select * from huge_table")
    (loop []
      (when-let [rows (-> "fetch 10 from cur" db/query not-empty)]
        (doseq [row rows]
          (process-a-row row))
        (recur))))

在这里，db/with-tx和db/execute!是db/query我自己在命名空间中声明的快捷方式db：

(def ^:dynamic
  *db* {:dbtype "postgresql"
        :connection-uri <some db url>)})

(defn query [& args]
  (apply jdbc/query *db* args))

(defn execute! [& args]
  (apply jdbc/execute! *db* args))

(defmacro with-tx
  "Runs a series of queries into transaction."
  [& body]
  `(jdbc/with-db-transaction [tx# *db*]
     (binding [*db* tx#]
       ~@body)))
于 2018-03-03T12:26:15.127 回答