11

请看下面的代码：

Public Class TypeTest
    Public variable1 As String
End Class

Public Class Form1

    Private Sub Form1_Load(ByVal sender As Object, ByVal e As System.EventArgs) Handles Me.Load
        Dim t1 As TypeTest = New TypeTest
        Test(t1)
        MsgBox(t1.variable1)
    End Sub

    Public Sub Test(ByVal t1 As TypeTest)
        t1.Variable1 = "Thursday"
    End Sub

End Class

form_load 中的消息框打印：Thursday，表示对象（TypeTest）是通过引用传递的。在调用的函数中使用 ByVal 和 ByRef 的 t1 争论有什么区别：

4

3 回答 3

21

由于您声明TypeTest为 a Class，这使其成为引用类型（而不是Structure用于声明值类型）。引用类型变量充当指向对象的指针，而值类型变量直接存储对象数据。

您的理解是正确的，它ByRef允许您更改参数变量的值，而ByVal不能。使用值类型时，和之间的区别ByVal非常ByRef明显，但是当您使用引用类型时，行为就不太预期了。您可以更改引用类型对象的属性值（即使它被传递ByVal）的原因是因为变量的值是指向对象的指针，而不是对象本身。更改对象的属性根本不会更改变量的值。该变量仍然包含指向同一对象的指针。

ByVal这可能会让你相信引用类型和引用类型之间没有区别ByRef，但事实并非如此。它们是有区别的。不同之处在于，当您将引用类型的参数传递给ByRef参数时，您调用的方法可以更改原始变量指向的对象。换句话说，该方法不仅能够更改对象的属性，而且还能够将参数变量完全指向不同的对象。例如：

Private Sub Form1_Load(ByVal sender As Object, ByVal e As System.EventArgs) Handles Me.Load
    Dim t1 As TypeTest = New TypeTest
    t1.Variable1 = "Thursday"
    TestByVal(t1)
    MsgBox(t1.variable1)  ' Displays "Thursday"
    TestByRef(t1)
    MsgBox(t1.variable1)  ' Displays "Friday"
End Sub

Public Sub TestByVal(ByVal t1 As TypeTest)
    t1 = New TypeTest()
    t1.Variable1 = "Friday"
End Sub

Public Sub TestByRef(ByRef t1 As TypeTest)
    t1 = New TypeTest()
    t1.Variable1 = "Friday"
End Sub
于 2013-10-31T13:28:23.157 回答
5

再举几个例子。一个显示 ByRef to ByVal 强制

Private Sub Button1_Click(sender As Object, e As EventArgs) Handles Button1.Click
    Dim tt As TypeTest = New TypeTest
    tt.variable1 = "FooBar"
    Debug.WriteLine("'1 " & tt.variable1)

    TestByVal1(tt)
    Debug.WriteLine("'2.1 " & tt.variable1)

    tt.variable1 = "FooBar"
    TestByVal2(tt)
    Debug.WriteLine("'2.2 " & tt.variable1)

    tt.variable1 = "FooBar"
    TestByRef(tt)
    Debug.WriteLine("'3 " & tt.variable1)

    tt.variable1 = "FooBar"
    TestByRef((tt)) 'note inner set of () force ref to val
    Debug.WriteLine("'4 " & tt.variable1)

    'debug output
    '1 FooBar
    '2.1 FooBar
    '2.2 Monday
    '3 Friday
    '4 FooBar
End Sub

Public Sub TestByVal1(ByVal t1 As TypeTest)
    t1 = New TypeTest()
    t1.variable1 = "Monday"
End Sub

Public Sub TestByVal2(ByVal t1 As TypeTest)
    t1.variable1 = "Monday"
End Sub

Public Sub TestByRef(ByRef t1 As TypeTest)
    t1 = New TypeTest()
    t1.Variable1 = "Friday"
End Sub
于 2013-10-31T14:11:11.307 回答
1

ByVal 实际上是复制当前变量的值并将其传递给函数。通过引用复制当前对函数的引用。让我们举个例子：

t1 是一个引用变量，其中包含 TypeTest 类型对象的地址，因此当您使用 ByVal 时，该地址被复制到函数中。最终你使用相同的对象。

真正有意义的是，对于 int、float 等基本变量。

示例：内部温度 =0；

temp 是一个包含值 0 的变量，因此在复制时传递 0。如果您使用引用，则将 temp 的地址 (&0) 传递给函数。

总而言之，ByRef 仅在基本类型而非复杂类型中更有意义。

于 2013-10-31T13:28:14.783 回答