71

我需要将一些来自编译脚本的信息传递到 Template Haskell 中。目前编译脚本将信息保存在系统环境中，所以我只是使用System.Environment.getEnvironmentWrapped in读取它runIO。有没有更好的方法，比如将一些参数传递给ghc（类似于-D...C 预处理器），或者在 TH 中专门为此目的设计的东西？

4

2 回答 2

14

既然这么多人对这个问题感兴趣，我会添加我目前的方法，也许有人会觉得它有用。如果 TH 允许在 GHC 的命令行上读取参数，最好的方法可能是-D，但目前似乎没有这样的实现。

一个简单的模块允许 TH 读取编译时环境。辅助函数还允许读取文件；例如从环境中读取配置文件的路径，然后读取该文件。

{-# LANGUAGE TemplateHaskell #-}
module THEnv
    (
    -- * Compile-time configuration
      lookupCompileEnv
    , lookupCompileEnvExp
    , getCompileEnv
    , getCompileEnvExp
    , fileAsString
    ) where

import Control.Monad
import qualified Data.Text as T
import qualified Data.Text.IO as T
import Language.Haskell.TH
import Language.Haskell.TH.Syntax (Lift(..))
import System.Environment (getEnvironment)

-- Functions that work with compile-time configuration

-- | Looks up a compile-time environment variable.
lookupCompileEnv :: String -> Q (Maybe String)
lookupCompileEnv key = lookup key `liftM` runIO getEnvironment

-- | Looks up a compile-time environment variable. The result is a TH
-- expression of type @Maybe String@.
lookupCompileEnvExp :: String -> Q Exp
lookupCompileEnvExp = (`sigE` [t| Maybe String |]) . lift <=< lookupCompileEnv
    -- We need to explicly type the result so that things like `print Nothing`
    -- work.

-- | Looks up an compile-time environment variable and fail, if it's not
-- present.
getCompileEnv :: String -> Q String
getCompileEnv key =
  lookupCompileEnv key >>=
  maybe (fail $ "Environment variable " ++ key ++ " not defined") return

-- | Looks up an compile-time environment variable and fail, if it's not
-- present. The result is a TH expression of type @String@.
getCompileEnvExp :: String -> Q Exp
getCompileEnvExp = lift <=< getCompileEnv

-- | Loads the content of a file as a string constant expression.
-- The given path is relative to the source directory.
fileAsString :: FilePath -> Q Exp
fileAsString = do
  -- addDependentFile path -- works only with template-haskell >= 2.7
  stringE . T.unpack . T.strip <=< runIO . T.readFile

它可以这样使用：

{-# LANGUAGE TemplateHaskell #-}
import THEnv
main = print $( lookupCompileEnvExp "DEBUG" )

然后：

  • runhaskell Main.hs打印Nothing；
  • DEBUG="yes" runhaskell Main.hs打印Just "yes"。
于 2014-01-01T17:05:58.537 回答
3

看起来你在这里尝试做的事情，ghc 中的 -D 选项似乎定义了一个编译时变量。

在这里，关于同一主题的问题似乎也回答了您问题的另一部分。据我所知，要进行条件编译，您可以执行以下操作：

    #ifdef MACRO_NAME
    //Do stuff here
    #endif
于 2013-12-25T21:24:24.143 回答