excel - 使用可变结束设置 VBA 范围

Question

我对 VBA 有点陌生，并且正在努力理解一些语法。

例如，我有一个范围 from a3:c13，我想将其设置为变量，以便稍后将其作为表数组传递给 vlookup。但是，范围是由用户输入根据其大小定义的。它总是从 开始A3，总是包括 columns A:C，但我不知道它会走多远。在这种情况下，我想我会将其设置为：

With range("a3")
    table_array = range(.cells(0,0), .End(xlDown).End(xlToRight)).Select
End With

但是，这似乎不起作用。我收到运行时错误：

Run-time Error '1004': Method '_Default' of object 'Range' failed.

Answer 1

假设列 A、B 和 C 具有相同的行数：

Sub Macro1()
    Set r = Range("A3")
    Set table_array = Range(r, r.End(xlDown)).Resize(, 3)
End Sub

Answer 2

您可以在 Col A:C 中找到最后一行，然后构建您的范围？

Sub Sample()
    Dim ws As Worksheet
    Dim LastRow As Long
    Dim Rng As Range

    '~~> Change this to the relevant sheet
    Set ws = ThisWorkbook.Sheets("Sheet1")

    With ws
        If Application.WorksheetFunction.CountA(.Cells) <> 0 Then
            LastRow = .Range("A:C").Find(What:="*", _
                          After:=.Range("A1"), _
                          Lookat:=xlPart, _
                          LookIn:=xlFormulas, _
                          SearchOrder:=xlByRows, _
                          SearchDirection:=xlPrevious, _
                          MatchCase:=False).Row
        Else
            LastRow = 1
        End If

        If Not LastRow < 3 Then
            Set Rng = .Range("A3:C" & LastRow)

            Debug.Print Rng.Address
        Else
            MsgBox "No Data found beyond A3"
        End If
    End With
End Sub