2

我想根据某些条件输出一个 xml。

这是我的输入 XML

<YIORDER01>
    <IDOC>
        <E1ORHDR>
            <E1OROPR>
                <VORNR>0010</VORNR>
                <E1OROPR_MAT>
                    <MATNR>M0003-01</MATNR>
                    <YE1OROPR_MAT>
                        <STTXT>REL</STTXT>
                        <MTART>ZPAR</MTART>
                        <POSTP>L</POSTP>
                    </YE1OROPR_MAT>
                </E1OROPR_MAT>
                <E1OROPR_MAT>
                    <MATNR>M0003-01</MATNR>
                    <YE1OROPR_MAT>
                        <STTXT>REL</STTXT>
                        <MTART>XYZ</MTART>
                        <POSTP>M</POSTP>
                    </YE1OROPR_MAT>
                </E1OROPR_MAT>
            </E1OROPR>
            <E1OROPR>
                <VORNR>0020</VORNR>
                <E1OROPR_MAT>
                    <MATNR>M0003-01</MATNR>
                    <YE1OROPR_MAT>
                        <STTXT>REL</STTXT>
                        <MTART>ZPAR</MTART>
                        <POSTP>L</POSTP>
                    </YE1OROPR_MAT>
                </E1OROPR_MAT>
            </E1OROPR>
        </E1ORHDR>
    </IDOC>
</YIORDER01>

输出是这样的。

<PartOrderList>
   <PartOrder>
      <OperationBONumber>0010</OperationBONumber>
      <PartOrderLine>
         <MaterialNumber>M0003-01</MaterialNumber>
         <ShipmentType>REL</ShipmentType>
      </PartOrderLine>
   </PartOrder>
   <PartOrder>
      <OperationBONumber>0020</OperationBONumber>
   </PartOrder>
</PartOrderList>

我的 XSLT 就是这个

<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
    <xsl:template match="YIORDER01">
        <xsl:element name="PartOrderList">
            <xsl:for-each select="IDOC/E1ORHDR/E1OROPR">
                <xsl:element name="PartOrder">
                    <xsl:element name="OperationBONumber">
                        <xsl:value-of select="VORNR"/>
                    </xsl:element>
                    <xsl:for-each select="E1OROPR_MAT">
                        <xsl:if test="YE1OROPR_MAT/MTART = &apos;ZPAR&apos; and YE1OROPR_MAT/POSTP = &apos;L&apos;">
                            <xsl:element name="PartOrderLine">
                                <xsl:element name="MaterialNumber">
                                    <xsl:value-of select="MATNR"/>
                                </xsl:element>
                                <xsl:element name="ShipmentType">
                                    <xsl:value-of select="YE1OROPR_MAT/STTXT"/>
                                </xsl:element>
                            </xsl:element>
                        </xsl:if>
                    </xsl:for-each>
                </xsl:element>
            </xsl:for-each>
        </xsl:element>
    </xsl:template>
</xsl:stylesheet>

这里的问题是，我不希望输出中出现第二个“PartOrder”标签，因为它没有任何“PartOrderLine”子标签。

xslt 中使用的规则：

  1. 为输入中的每个“E1OROPR”在输出中创建一个“PartOrder”标签
  2. 仅当“MTART”=“ZPAR”和“POSTP”=“L”时在“PartOrder”内创建“PartOrderLine”标签
  3. 如果输出中没有有效的“PartOrderLine”标签，请勿创建任何“PartOrder”标签。

使用我的 xslt 我能够实现规则 1 和 2，但不知道如何实现规则 3。
有什么方法可以使用 xslt 实现这一点？

请帮忙。

4

2 回答 2

3

您需要将条件作为谓词添加到外部for-each选择表达式，以便您只为每个您知道将生成至少一个的元素PartOrderLine

<xsl:for-each select="IDOC/E1ORHDR/E1OROPR[
      E1OROPR_MAT/YE1OROPR_MAT[MTART = 'ZPAR' and POSTP = 'L']]">
于 2013-10-29T14:12:23.727 回答
0

仅供参考：这就是我的处理方式。这种方法的优点是：

  • 您的有效线路规则仅定义一次，因此如果您更改逻辑，它将同时更改 PO 和 POLine。
  • 如果您想修改任何内容，每条数据都很容易找到。
  • 所有模板都可以并行运行，（通常）使其在多处理器机器上更快。

. 

<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" version="1.0">

  <xsl:output method="xml" indent="yes"/>

  <!-- Part Order List -->
  <xsl:template match="/*">
    <xsl:element name="PartOrderList">
      <xsl:apply-templates select=".//E1OROPR" /> 
    </xsl:element>
  </xsl:template>

  <!-- Part Order List > Part Order -->
  <xsl:template match="//E1OROPR">
    <xsl:variable name="IsValid">
      <xsl:call-template name="HasOrIsValidPOLine" />
    </xsl:variable>
    <xsl:if test="$IsValid='VALID'"> <!-- only display the part order if there's a valid line under it-->
      <xsl:element name="PartOrder">
        <xsl:apply-templates select=".//VORNR" />
        <xsl:apply-templates select=".//E1OROPR_MAT" />
      </xsl:element>
    </xsl:if>
  </xsl:template>

  <!-- Part Order List > Part Order > Operational BO Number -->
  <xsl:template match="//VORNR">
    <xsl:element name="OperationBONumber">
      <xsl:value-of select="text()"/>
    </xsl:element>
  </xsl:template>

  <!-- Part Order List > Part Order > Part Order Line -->
  <xsl:template match="//E1OROPR_MAT">
    <xsl:variable name="IsValid">
      <xsl:call-template name="HasOrIsValidPOLine" />
    </xsl:variable>
    <xsl:if test="$IsValid='VALID'">
      <!-- only display the part order line if it's valid-->
      <xsl:element name="PartOrderLine">
        <xsl:apply-templates select=".//MATNR" />
        <xsl:apply-templates select=".//STTXT" />
      </xsl:element>
    </xsl:if>
  </xsl:template>

  <!-- Part Order List > Part Order > Part Order Line > Material Number -->
  <xsl:template match="//MATNR">
    <xsl:element name="MaterialNumber">
      <xsl:value-of select="text()"/>
    </xsl:element>
  </xsl:template>

  <!-- Part Order List > Part Order > Part Order Line > Shipment Type -->
  <xsl:template match="//STTXT">
    <xsl:element name="ShipmentType">
      <xsl:value-of select="text()"/>
    </xsl:element>
  </xsl:template>

  <xsl:template name="HasOrIsValidPOLine">
    <xsl:choose>
      <xsl:when test=".//MTART/text() = 'ZPAR' and .//POSTP/text() = 'L'">VALID</xsl:when>
      <xsl:otherwise>INVALID</xsl:otherwise>
    </xsl:choose>
  </xsl:template>

</xsl:stylesheet>

也就是说，可能有很多工作可以进一步改进/您选择哪个选项应该取决于您最喜欢使用的代码（在一定程度上；显然任何新方法都有一个学习曲线，这可能会导致最初的不适，所以这应该考虑到长期考虑）。

于 2013-10-29T14:54:16.510 回答