1

软件包 tdbc::mysql 和 tdbc::postgresql 需要 DLL libmysql.dll 和 libpq.dll 在 PATH 中。将此 dll 包含到单个 starpack 中的最佳方法是什么？

现在我正在使用以下 pkgIndex.tcl： 

if {[catch {package require Tcl 8.6}]} {
    return
}
package ifneeded tdbc::postgres 1.0.0 [list apply {{dir} {
  if { $::tcl_platform(os) eq "Windows NT" &&
        ($::tcl_platform(machine) eq "intel" || 
         $::tcl_platform(machine) ne "amd64") } {
    foreach n {libpq libeay32 ssleay32 comerr32 gssapi32 
               k5sprt32 krb5_32 libiconv-2 libintl-8} {     
      file copy -force [file join $dir ${n}.dll] \
        [file join $::env(WINDIR) System32 ${n}.dll]
    }
  }
  source [file join $dir tdbcpostgres.tcl]
  load [file join $dir tdbcpostgres100.dll] tdbcpostgres
}} $dir]

但这看起来非常难看。

我试图找到一种方法将必要的库复制到解释器用来加载 dll 的临时文件夹中。但是通过检查 Tcl 源代码，发现临时目录的名称是不可能用于脚本的。

更新：目前，我决定使用 twapi 来确定 Tcl 解释器使用的临时文件夹的名称。我得到以下代码：

if {[catch {package require Tcl 8.6}]} {
    return
}
package ifneeded tdbc::postgres 1.0.0 [list apply {{dir} {
  if { $::tcl_platform(os) eq "Windows NT" &&
        ($::tcl_platform(machine) eq "intel" || 
         $::tcl_platform(machine) eq "amd64") } {
    package require twapi
    set _ [file dirname [lindex [lsearch -inline -index 1 -glob \
          [twapi::get_process_modules [twapi::get_current_process_id] -path] \
          {*/twapi_base*.dll}] 1]]
    if { $_ eq "." } { 
      error "couldn't find temp folder name for tdbc::postgres support library" 
    }
    foreach fn [glob -types f -tails -directory $dir "*.dll"] {
      if { [string match -nocase "tdbcpostgres*" $fn] } continue
      file copy -force [file join $dir $fn] [file join $_ $fn]
    }
  } {
    set _ [pwd]
  }
  source [file join $dir tdbcpostgres.tcl]
  set tpwd [pwd]
  cd $_
  catch { load [file join $dir tdbcpostgres100.dll] tdbcpostgres } r o
  cd $tpwd
  return -options $o $r
}} $dir]

但是程序退出后删除临时文件仍然存在问题。我只看到一个解决方案：在程序开始时扫描文件夹$::env(TEMP)并尝试删除所有名为TCLXXXXXXXX.

4

2 回答 2

1

如果没有管理员访问权限，将文件复制到的“解决方案”c:\windows\system32将无法工作，而大多数从 Windows Vista 开始的应用程序都没有。（您必须选择“以管理员身份运行”）那么 system32 目录中的新文件呢？你只需更换它们。

一些替代方案：

  • 自己将所有 dll 复制到一个临时目录，切换到该目录并加载 dll（利用您在 Windows 上查看 . 的事实）：

    package ifneeded tdbc::postgres 1.0.0 [list apply {{dir} {
    set dest [file join $::env(TEMP) tcl[file seconds]]
    file mkdir $dest
    foreach dll [glob -dir $dir *.dll] {
        file copy $dll $dest
    }
    set cwd [pwd]
    cd $dest
    catch {
        source [file join $dir tdbcpostgres.tcl]
        load [file join $dest tdbcpostgres100.dll] tdbcpostgres
    } res opt
    cd $cwd
    return -options $opt $res
}} $dir]

    但是我们应该如何清理它呢？

  • 将dll编译到starpack中。那很难。

  • 自己编译扩展，所以它没有任何依赖。我不知道该怎么做。

  • 自己加载每个所需的 dll。这是我最喜欢的解决方案，但它需要 twapi：

    package ifneeded tdbc::postgres 1.0.0 [list apply {{dir} {
    package require twapi
    foreach dll [glob -dir $dir *.dll] {
        ::twapi::load_library $dll
    }
    source [file join $dir tdbcpostgres.tcl]
    load [file join $dir tdbcpostgres100.dll] tdbcpostgres
}} $dir]
于 2013-10-26T23:26:58.270 回答
1

该技巧的主要问题是它需要对系统目录的写访问权。你不想那样做。但是，如果找不到引导符号，您可以改为使用load不会撤消库加载的事实。（这是 Tcl 通常的“在故障模式下尽可能干净”模型的变体，但它在这里非常有用。）

package ifneeded tdbc::postgres 1.0.0 [list apply {{dir} {
    global tcl_platform
    if {$tcl_platform(os) eq "Windows NT" && $tcl_platform(machine) ne "amd64"} {
        foreach n {libpq libeay32 ssleay32 comerr32 gssapi32 
                   k5sprt32 krb5_32 libiconv-2 libintl-8} {
            if {![file exist [file join $::env(WINDIR) System32 ${n}.dll]]} {
                # Leverage Tcl's built-in loading magic
                catch {load [file join $dir ${n}.dll]}
            }
        }
    }
    source [file join $dir tdbcpostgres.tcl]
    load [file join $dir tdbcpostgres100.dll] tdbcpostgres
}} $dir]

这仍然不是很优雅，但是拦截真正的依赖加载机制非常困难；预加载更容易。（如果用户已经拥有特定的库，我也停止了代码的欺骗。）

正确的解决方法是构建tdbcpostgres100.dll具有其他依赖项的静态库。我猜这是一项相当多的工作；我没有尝试这样做。

于 2013-10-27T00:54:25.303 回答