perl - 无法在 wxPerl 中触发 EVT_KEY_DOWN

Question

在这种情况下$self是一个子类，Wx::Frame我可以将控件、菜单等添加到框架中。但是我不能添加关键事件。我正在使用以下内容添加关键事件：

  EVT_KEY_DOWN($self,  \&_process_char);

_process_char 函数如下所示：

sub _process_char {
   my ($evt) = @_;
   warn 'key pressed';
}

事件不会触发。我究竟做错了什么？如何让按键事件与 wxperl 一起使用？

Answer 1

它与事件传播有关——一个 textctrl 处理 keydown/keyup 事件，而默认的（默认 textctrl 处理程序）不会将这些事件向上传播到帧。如果您希望您的处理程序被调用绑定到 wxTheApp() 或 textctrl。这是一个并非所有密钥都被传播的示例

#!/usr/bin/perl --
use strict; use warnings;
use Wx ();

Main( @ARGV );
exit( 0 );

sub Main {
    local $|  = 1;
    my $app   = Wx::SimpleApp->new;
    my $frame = Wx::Frame->new( undef, -1, "type stuff ", ([250,150])x2 );
    my $text  = Wx::TextCtrl->new( $frame, -1,"", );

    $app->SetTopWindow( $frame );

    my $target = @_ ? $frame : $text;
    Wx::Event::EVT_KEY_DOWN( $target ,  \&Frobnicate );
    Wx::Event::EVT_KILL_FOCUS($app,  sub{  Wx::wxTheApp()->ExitMainLoop });

    $app->{counter} = 0;
    $frame->Show;
    $text->SetFocus;
    $app->MainLoop;
}

sub Frobnicate {
    my( $widget, $kev )=@_;
    my $app   = Wx::wxTheApp();
    my $count = $app->{counter}++;
    my $frame = $app->GetTopWindow;
    my $title = $frame->GetTitle;
    $title =~ s{\d*+$}{$count};
    $frame->SetTitle( $title );
    $kev->Skip if 0 == $count % 4; ## sometimes :P
}

• http://docs.wxwidgets.org/trunk/overview_events.html
• http://docs.wxwidgets.org/trunk/classwx_key_event.html
• 在 wxFrame 上处理来自 wxTextCtrl 的事件 - C++/wxWidgets
• wxWidgets 论坛 • 查看主题 - 无法在 wxPanel 中捕获 EVT_KEY_DOWN 或 EVT_CHAR
• http://wiki.wxwidgets.org/Catching_key_events_globally

此外，您调用处理程序_process_char但您使用 EVT_KEY_DOWN - EVT_CHAR 仅用于字符 :)

更新：对于笔记本示例，将（在上面的示例中）替换$text为

    my $noteb = Wx::Notebook->new( $frame );
    my $text  = Wx::TextCtrl->new( $noteb, -1,"", );
    $noteb->AddPage( $text, "you myst type stuff");
    Wx::Event::EVT_KEY_DOWN( $app,  \&Frobnicate );