1

我有一个脚本，我目前正在使用它来检查该网络何时启动或关闭。它写入 pinglog.txt 。

对于我的一生，我无法弄清楚当网络出现故障时如何让它写入事件日志。它在哪里说：

   Call logme(Time & " - "  & machine & " is not responding to ping, CALL FOR 

   HELP!!!!",strLogFile)

这就是我需要写入事件日志的内容“机器无法响应 ping，请寻求帮助！！！！

 'Ping multiple computers and log when one doesn't respond.
 '################### Configuration #######################

 'Enter the IPs or machine names on the line below separated by a semicolon
  strMachines = "4.2.2.2;8.8.8.8;8.8.4.4"

  'Make sure that this log file exists, if not, the script will fail.
   strLogFile = "c:\logs\pinglog.txt"

   '################### End Configuration ###################

   'The default application for .vbs is wscript. If you double-click on the script,
   'this little routine will capture it, and run it in a command shell with cscript.
    If Right(WScript.FullName,Len(WScript.FullName) - Len(WScript.Path)) <>       "\cscript.exe" Then
           Set objWMIService = GetObject("winmgmts:    {impersonationLevel=impersonate}!\\.\root\cimv2")
        Set objStartup = objWMIService.Get("Win32_ProcessStartup")
        Set objConfig = objStartup.SpawnInstance_
        Set objProcess = GetObject("winmgmts:root\cimv2:Win32_Process")
        objProcess.Create WScript.Path + "\cscript.exe """ + WScript.ScriptFullName + """", Null, objConfig, intProcessID
    WScript.Quit
    End If

    Const ForAppending = 8
    Const ForReading = 1
    Const ForWriting = 2

    Set objFSO = CreateObject("Scripting.FileSystemObject")

    If objFSO.FileExists(strLogFile) Then
    Set objFolder = objFSO.GetFile(strLogFile)
    Else
Wscript.Echo "Log file does not exist. Please create " & strLogFile
WScript.Quit
  End If

 aMachines = Split(strMachines, ";")

    Do While True 
    For Each machine In aMachines
            Set objPing = GetObject("winmgmts:{impersonationLevel=impersonate}")._
            ExecQuery("select * from Win32_PingStatus where address = '"_
            & machine & "'")
            For Each objStatus In objPing
                       If IsNull(objStatus.StatusCode) Or objStatus.StatusCode<>0 Then 
                                Call logme(Time & " - "  & machine & " is not responding to   ping, CALL FOR 

  HELP!!!!",strLogFile) 
                       Else
                                WScript.Echo(Time & " + "  & machine & " is responding to       ping, we are good")    
                    End If
               Next
        Next
        WScript.Sleep 5000
  Loop

  Sub logme(message,logfile)
    Set objTextFile = objFSO.OpenTextFile(logfile, ForAppending, True)
    objtextfile.WriteLine(message)
    WScript.Echo(message)
    objTextFile.Close
  End Sub

对不起，代码中的间距。谢谢您的帮助

4

1 回答 1

9

使用 WshShell 对象：

对象.LogEvent（intType，strMessage [，strTarget ]）

对象WshShell 对象。

intType表示事件类型的整数值。

strMessage包含日志条目文本的字符串值。

strTarget可选。字符串值，指示存储事件日志的计算机系统的名称（默认为本地计算机系统）。仅适用于 Windows NT/2000。

像这样：

Option Explicit

Dim shl

Set shl = CreateObject("WScript.Shell")

Call shl.LogEvent(1,"Some Error Message")

Set shl = Nothing
WScript.Quit

LogEvent 的第一个参数是事件类型：

0    SUCCESS
1    ERROR
2    WARNING
4    INFORMATION
8    AUDIT_SUCCESS
16   AUDIT_FAILURE

编辑：更多细节

用这个替换你的整个“logme”子例程

  Sub logme(t,m)
      Dim shl

      Set shl = CreateObject("WScript.Shell")

      Call shl.LogEvent(t,m)

      Set shl = Nothing
  End Sub

然后更改此行：

Call logme(Time & " - "  & machine & " is not responding to   ping, CALL FOR HELP!!!!",strLogFile)

到：

Call logme(1, machine & " is not responding to   ping, CALL FOR HELP!!!!")
于 2013-10-25T12:35:31.060 回答