delphi - 删除 BMP 背景并使用 Delphi 转换为透明 PNG

Question

我有一个 TBitmap，在 TBitmap 内部加载了一个“地图图像”（地图图像）。这张地图图像有一个白色背景和很多黑线（没有抗锯齿只有两种颜色的白色背景和黑线）。

现在我必须这样做：

• 从 TBitmap 中移除白色背景（透明背景和黑线）；
• 如果可能且仅在可能的情况下将黑线颜色替换为另一种颜色；
• 将结果保存为透明的PNG图像；

我不知道这些是否可能。建议？

注意如果可能的话，我想避免使用课程的第 3 部分或 VCL。如果需要，我可以使用 FreeImage 库，因为我只是在我的项目中使用它。我使用德尔福 XE3。

Answer 1

将像素格式更改为 pf1Bit。创建一个包含 2 个条目的调色板，将 TPaletteEntry 的值更改为所需的颜色值（在所示示例中为红色）。创建一个 TPNGImage，分配位图并设置 PNG 的透明度。

implementation
uses pngimage;
{$R *.dfm}

Type
  TMyPalette = Packed Record
     palVersion : Word;
     palNumEntries : Word;
     palPalEntry : Array [0..1] of TPaletteEntry;
   End;

Procedure ChangeBlackColor(bmp:TBitMap);
var
 pal:TMyPalette;
begin
   bmp.PixelFormat := pf1Bit;
   bmp.HandleType  := bmDIB;
    With pal Do
    Begin
      palVersion:=$0300;
      palNumEntries:=2;
      palPalEntry[0].peRed:= $FF;
      palPalEntry[0].peGreen:=$00;
      palPalEntry[0].peBlue:= $00;
      palPalEntry[0].peFlags:=PC_RESERVED;
      palPalEntry[1].peRed:= $FF;
      palPalEntry[1].peGreen:=$FF;
      palPalEntry[1].peBlue:= $FF;
      palPalEntry[1].peFlags:=PC_RESERVED;
    End;
   bmp.Palette := CreatePalette(pLogPalette(@pal)^)
end;



procedure TForm3.Button1Click(Sender: TObject);
var
 png:TPngimage;
 bmp:TBitmap;
begin
  // sample image
  Image1.Canvas.Rectangle(0,0,Image1.Width-1,Image1.Height-1);
  Image1.Canvas.Ellipse(1,1,Image1.Width,Image1.Height);



  bmp := Image1.Picture.Bitmap;

  ChangeBlackColor(bmp);

  png:=TPngimage.Create;
  try
     png.Assign(bmp);
     png.TransparentColor := clWhite;
     png.Transparent := true;
     Image2.Picture.Assign(png);
  finally
    png.Free;
  end;
end;