0

我有一个看起来像这样的大型 xml 文档：

<?xml version="1.0" encoding="UTF-8" ?>
<Data>
  <aTable>
    <aTableRow Col1="1" Col2="someText"/>
    <aTableRow Col1="2" Col2="newText"/>
    ...
  </aTable>
  <anotherTable>
    <anotherTableRow Col3="someText" Col4="42"/>
    <anotherTableRow Col3="myText" Col4="34"/>
    ...
  </anotherTable>
  ...
</Data>

我需要在相应的 SQL INSERT 语句序列中转换文档。就像是：

INSERT INTO aTable (Col1, Col2) VALUES (1, "someText")

我已经有了从“表”到相应 SQL 语句的转换，但是 xslt 输出是按照文档的相同顺序生成的。

有没有办法在 aTable 之前有例如 anotherTable ？

编辑

感谢您的评论和回答。阅读它们，我意识到我最初的问题并不那么清楚。我会尝试添加更多细节。

我已经生成了一个模板，它可以在一系列插入语句中正确转换 xml 数据，假设这个模板被命名为“insertGeneration”。

然后我写了类似的东西：

<xsl:template match="Data/anotherTable">
  <xsl:call-template name="insertGeneration"/>
</xsl:template>

<xsl:template match="Data/aTable">
  <xsl:call-template name="insertGeneration"/>
</xsl:template>

我希望按此顺序生成输出，即 all INSERT INTO anotherTablebefore all INSERT INTO aTable。但生成的顺序与源文档相同。

我需要一个特定的顺序，否则在执行 SQL 脚本时我可能会违反外键约束。

我的 xslt 处理器是 Visual Studio 2005。好吧，不是一个紧凑的 xslt 处理器；-)

4

1 回答 1

1 
<xsl:output method="text" encoding="UTF-8" />

<xsl:template match="Data">
  <xsl:apply-templates select="*/*">
    <xsl:sort select="name(..)" case-order="lower-first" />
  </xsl:apply-templates>
</xsl:template>

<xsl:template match="Data/*/*">
  <xsl:text>INSERT INTO [</xsl:text>
  <xsl:value-of select="name(..)" />
  <xsl:text>] (</xsl:text>
  <xsl:apply-templates select="@*" mode="names" />
  <xsl:text>) VALUES (</xsl:text>
  <xsl:apply-templates select="@*" mode="values" />
  <xsl:text>)&#xA;</xsl:text>
</xsl:template>

<xsl:template match="Data/*/*/@*" mode="names">
  <xsl:text>[</xsl:text>
  <xsl:value-of select="name()" />
  <xsl:text>]</xsl:text>
  <xsl:if test="position() &lt; last()">, </xsl:if>
</xsl:template>

<xsl:template match="Data/*/*/@*" mode="values">
  <xsl:text>'</xsl:text>
  <xsl:call-template name="string-replace">
    <xsl:with-param name="search">'</xsl:with-param>
    <xsl:with-param name="replace">''</xsl:with-param>
  </xsl:call-template>
  <xsl:text>'</xsl:text>
  <xsl:if test="position() &lt; last()">, </xsl:if>
</xsl:template>

这会产生与 T-SQL 兼容的输出，如下所示：

INSERT INTO [anotherTable] ([Col3], [Col4]) VALUES ('someText', '42')
INSERT INTO [anotherTable] ([Col3], [Col4]) VALUES ('myText', '34')
INSERT INTO [aTable] ([Col1], [Col2]) VALUES ('1', 'some''Text')
INSERT INTO [aTable] ([Col1], [Col2]) VALUES ('2', 'newText')

如有必要，将代码调整为数据库的语法。

这使用表名的字典顺序。如果您想要不同的顺序，请<xsl:sort>相应地更改或使用几个单独<xsl:apply-templates>的顺序来产生所需的顺序。（请注意，一些 XSLT 处理器似乎忽略了该case-order参数。）

请注意，这string-replace是一个实现字符串替换功能的命名模板（XSLT 1.0 所必需的）。如果您有 XSLT 2.0，您可以简单地使用内置string-replace()函数。

<xsl:template name="string-replace">
  <xsl:param name="subject" select="string()" />
  <xsl:param name="search" />
  <xsl:param name="replace" />

  <xsl:variable name="head" select="substring-before($subject, $search)" />
  <xsl:variable name="tail" select="substring-after($subject, $search)" />
  <xsl:variable name="found" select="$head or $tail" />

  <xsl:if test="not($found)">
    <xsl:value-of select="$subject" />
  </xsl:if>

  <xsl:if test="$found">
    <xsl:value-of select="$head" />
    <xsl:value-of select="$replace" />
    <xsl:call-template name="string-replace">
      <xsl:with-param name="subject" select="$tail" />
      <xsl:with-param name="search" select="$search" />
      <xsl:with-param name="replace" select="$replace" />
    </xsl:call-template>
  </xsl:if>
</xsl:template>
于 2013-10-23T15:55:46.347 回答