15

我需要获取目录中的所有文件名并将它们存储在命令行中的某个变量中。

我遇到了这个

`dir /s /b > print.txt`

但这会将文件名打印到 txt 文件中。

如何将这些名称存储在变量中？

4

3 回答 3

22

我假设您真的是指 Windows 批处理文件，而不是 DOS。

批处理环境变量限制为 8191 个字符，因此可能无法将所有文件路径放入一个变量中，具体取决于文件数和平均文件路径长度。

如果文件名包含空格，则应引用它们。

假设它们适合一个变量，您可以使用：

@echo off
setlocal disableDelayedExpansion
set "files="
for /r %%F in (*) do call set files=%%files%% "%%F"

CALL 语句相当慢。使用延迟扩展会更快，但是如果启用了延迟扩展，则扩展%%F会破坏包含的任何值。!多做一点工作，您就可以拥有一个快速安全的延迟扩展版本。

@echo off
setlocal disableDelayedExpansion
set "files=."
for /r %%F in (*) do (
  setlocal enableDelayedExpansion
  for /f "delims=" %%A in ("!files!") do (
    endlocal
    set "files=%%A "%%F"
  )
)
(set files=%files:~2%)

如果文件名不适合一个变量，那么您应该求助于一个伪值数组，每个文件一个。在下面的脚本中，我使用 FINDSTR 为 DIR 输出的每一行加上行号前缀。我使用行号作为数组的索引。

@echo off
setlocal disableDelayedExpansion
:: Load the file path "array"
for /f "tokens=1* delims=:" %%A in ('dir /s /b^|findstr /n "^"') do (
  set "file.%%A=%%B"
  set "file.count=%%A"
)

:: Access the values
setlocal enableDelayedExpansion
for /l %%N in (1 1 %file.count%) do echo !file.%%N!
于 2013-10-23T12:43:35.237 回答
5

正如@Matt 所说，使用批处理文件。

setlocal enabledelayedexpansion
set params=
for /f "delims=" %%a in ('dir /s/b') do set params=!params! %%a
于 2013-10-23T12:33:30.117 回答
1 
setlocal enableDelayedExpansion
set /a counter=0
for /f %%l in ('dir /b /s') do (
 set /a counter=counter+1
 set line_!counter!=%%l
)
set line_

如果您想将所有内容存储在一个变量中，请检查以下内容： 解释 dos-batch newline variable hack 的工作原理

于 2013-10-23T12:31:59.373 回答