4

我想我前段时间确实问过类似的问题，但由于 API 不稳定而没有回答。所以我在等待 0.13 过去。我不确定提出类似问题是否正确......？

runChildrenWith(Text)解释和mapSplices编译拼接世界的替代方案是什么？（这种组合似乎是最常见的）如果可能的话，我真的很感激一些代码示例。

如果我理解正确，我们将所有应用程序拼接在一起，然后将它们添加到heistInit. 任何人都可以展示如何做吗？

拼接绑定标签在整个应用程序中是否必须是唯一的？

是否有完整的 snap 项目utilising新的 API 和编译的拼接，以便我可以阅读和学习？

谢谢你。

- 更新 -

下面的答案很好。但不幸的是，有些部分（带镜片的部分）让我更加困惑。如果我理解正确，这是拼接字符串的简单方法：

mySplice = "testSplice" ## testSplice
  where testSplice = return $ C.yieldRuntimeText $ do
          return "text to be spliced"

如果我需要多次运行拼接字符串，比如在 5 个表中，我会这样做：

mySplices = C.manyWithSplices C.runChildren mySplice

这个对吗？

我在尝试在抢劫配置中添加接头时遇到一堆错误。

addConfig h $ mempty
 {
   hcCompiledSplices = "mySplice" ## mySplice -- or mySplices
 }

我哪里错了？对不起，很慢。

我真正需要的（只是现在我可以理解）是拼接并显示一个我从数据库接收到的简单字符串。

-- 更新 2 --

感谢 Daniel 的极有帮助的回答，我终于可以开始工作了。

到目前为止，我得到了两种代码变体。

第一个，感谢丹尼尔

stringSplice :: Monad n => C.Splice n
stringSplice = C.manyWithSplices C.runChildren splicefuncs (return ["aa","bb","cc"])
  where
    splicefuncs = "string" ## (C.pureSplice . C.textSplice $ id)

和秒

testSplice :: C.Splice (Handler App App)
testSplice = return $ C.yieldRuntimeText $ return "text to be spliced"

在哪里

(C.pureSplice . C.textSplice $ id)

产生类似的结果

return $ C.yieldRuntimeText $ return "text to be spliced"

以上有区别吗？任何情况下，人们会更喜欢另一种情况吗？它们似乎产生了相同的结果。

编译的拼接库中有一个“deferMany”函数，根据文档，它产生与解释库中的 mapSplices 相似的结果。我们可以用它来代替“C.manyWithSplices C.runChildren”的组合吗？

4

1 回答 1

6

假设您要显示有关使用已编译拼接的人员列表的信息（假设我们从生成的脚手架开始snap init。）

带有虚拟值的非常简单的_persons.tpl模板将类似于

<body>
    <person>
        <div>
            <h1><name>dummy name</name></h1>
            <p><age>77</age></p> 
            <p><location>jauja</location></p> 
        </div>
    </person>
</body>

其中person, name, age, 和location是要拼接的标签。

我们定义了一个简单的 Snaplet 来保存信息

data Foo = Foo
    {
        _persons :: [Person]
    }

makeLenses ''Foo

data Person = Person
    {
        _name :: Text
    ,   _age :: Int
    ,   _location :: Text
    }   

makeLenses ''Person

我们将其添加到App记录中：

data App = App
    { _heist :: Snaplet (Heist App)
    , _sess :: Snaplet SessionManager
    , _auth :: Snaplet (AuthManager App)
    , _foo :: Snaplet Foo
    }

我们将以下内容添加到应用初始化程序中

f <- nestSnaplet "foo" foo $ makeSnaplet "foo" "Foo Snaplet" Nothing $ return $ Foo $ 
        [ Person "Ricardo" 33 "Los Cantones" 
        , Person "Luis" 38 "Montealto" 
        ]

...

return $ App h s a f

此函数构造一个返回人员列表的 Handler（使用viewfrom Control.Lens）：

personH :: SnapletLens b Foo -> Handler b b [Person] 
personH l = withTop l $ view persons <$> get

RuntimeSplice此函数从生成人员列表的a 构造适当的编译拼接。RuntimeSplices 表示只能在运行时知道的信息，而不是加载时：

personSplice :: Monad n => RuntimeSplice n [Person] -> C.Splice n
personSplice = C.manyWithSplices C.runChildren splicefuncs 
    where
    splicefuncs = mconcat  
        [ "name" ## (C.pureSplice . C.textSplice $ view name)
        , "age" ## (C.pureSplice . C.textSplice $ T.pack . show . view age)
        , "location" ## (C.pureSplice . C.textSplice $ view location)
        ]

并且此功能可用于在全局 Heist 配置中注册拼接。请注意，我们将 提升Handler为 a RuntimeSplice：

addPersonSplices :: HasHeist b => Snaplet (Heist b) -> 
                                  SnapletLens b Foo -> 
                                  Initializer b v ()
addPersonSplices h l = addConfig h $ mempty 
   {
      hcCompiledSplices = "person" ## (personSplice . lift $ personH l) 
   }

请务必将此行添加到应用程序初始化程序：

addPersonSplices h foo

并将以下对添加到应用程序的路由中：

("/persons",  cRender "_persons")

如果您现在运行服务器，导航到http://127.0.0.1:8000/persons应该会显示列表。

更新

对于更简单的情况（没有复杂的记录，没有镜头），您只想显示字符串列表。

模板可能类似于：

<body>
    <strings>
        <p><string>dummy value</string></p>
    </strings>
</body>

顶级拼接将是：

stringSplice :: Monad n => C.Splice n
stringSplice = C.manyWithSplices C.runChildren splicefuncs (return ["aa","bb","cc"])
    where
    splicefuncs = "string" ## (C.pureSplice . C.textSplice $ id)

这意味着“当我们遇到与此拼接关联的标签时，执行一个生成字符串列表的操作，并为每个字符串呈现标签的内容，用当前字符串替换string标签”。

请注意，manyWithSplices的签名会强制 右边的东西(##)具有 type RuntimeSplice n Text -> Splice n。这里id有类型Text -> Text。C.TextSplice将其转换为 type Text -> Builder，并C.pureSplice执行最终转换为 a RuntimeSplice n Text -> Splice n。

代替(return ["aa","bb","cc"])您可以提供一个更复杂的操作来连接数据库并从那里提取字符串。

注册此拼接的函数将是：

addStringSplices :: HasHeist b => Snaplet (Heist b) -> Initializer b v ()
addStringSplices h = addConfig h $ mempty 
    {
          hcCompiledSplices = "strings" ## stringSplice
    }
于 2013-10-23T23:40:15.353 回答