1

我有一个包含两列数据的文件。绘制时，它看起来像gnuplot 图像

绿线显示平均值。我想在 Y 轴上显示平均值。是否可以？代码：

set style data lines
set termoption enhanced
set term png
set title "17th oct"
stats 'data/17-10-2013' using 1:2 nooutput
set xdata time
set timefmt "%s"
set format x "%H"
set output "images/17_DB.png"
plot "data/17-10-2013" using 1:3 title " Data" , STATS_mean_y title " Mean"

4

1 回答 1

1

以下是显示值的三个不同选项：

set term pngcairo enhanced
set output "images/17_DB.png"

set title "17th oct"
stats 'data/17-10-2013' using 1:2 nooutput
set xdata time
set timefmt "%s"
set format x "%H"

# first option    
set ytics add (sprintf('%.1f', STATS_mean_y) STATS_mean_y)

# second option
set ytics add ('' STATS_mean_y)
set rmargin 3
set label left at graph 1.05,first STATS_mean_y sprintf('%.1f', STATS_mean_y)

set style data lines

# third option inside the key label
plot "data/17-10-2013" using 1:3 title "Data" , \
     STATS_mean_y title sprintf("Mean = %.1f", STATS_mean_y)

这里有一些关于不同选项的注释：

  1. 第一个选项是最简单的，但标签可能与另一个标签重叠（此处为0）。
  2. 第二个选项添加一个空的市长，并将标签放在右侧。这需要手动增加右边距（您可能需要使用其他值，例如set rmargin 2其他坐标）。
  3. 第三个选项只是将值放在键（图例）条目中。

对于更好的x轴，您可能需要添加set autoscale xfix，它可以让您摆脱右侧的空白空间。

于 2013-10-22T12:08:38.703 回答