delphi - 如何画抛物线

Question

我使用 Lazarus 是因为我真的很喜欢这些TChart组件。我制作了一个程序来解决一些不等式，例如：

(Delta = Discriminant) 2x^2+6x+4>0 的解是x<-2和x>-1。这是正确的，但正如您所见，我在TPicture下面有一个组件，它显示了带有图表的图片。我是用 Gimp 做的。

我想使用一些合适的组件制作图表。正如我已经说过的，我在 Lazarus 上找到了它们，但是你知道 Delphi XE5 上是否也有任何方法吗？我在哪里可以看看？

Answer 1

首先，你的集合符号很奇怪。您的意思是 S = (−∞, −2) ∪ (−1, ∞)，即 S 是两个开区间的并集。您也可以写成 S = [−2, −1]^C 或 S = {x ∈ ℝ: x < −2 或 x > −1}。另外，您的图片肯定不是抛物线；它看起来更像双曲线。

无论如何，绘制函数f : ℝ → ℝ 的图形很简单。您只需要处理逻辑坐标系和屏幕坐标系之间的坐标转换。定义

type
  TRealVector = record
    X, Y: real;
  end;

作为ℝ²中的一个点，您的地图是

const
  xmin = -10;
  xmax = 10;
  ymin = -10;
  ymax = 10;

function TForm5.LogToScreen(LogPoint: TRealVector): TPoint;
begin
  result.X := round(ClientWidth * (LogPoint.X - xmin) / (xmax - xmin));
  result.Y := ClientHeight - round(ClientHeight * (LogPoint.Y - ymin) / (ymax - ymin));
end;

function TForm5.ScreenToLog(ScreenPoint: TPoint): TRealVector;
begin
  result.X := xmin + (ScreenPoint.X / ClientWidth) * (xmax - xmin);
  result.Y := ymin + (ymax - ymin) * (ClientHeight - ScreenPoint.Y) / ClientHeight;
end;

然后你只需要情节！

procedure TForm5.FormPaint(Sender: TObject);
var
  PrevPoint, CurrPoint: TPoint;
  x: integer;
  logx: real;
  logy: real;
  y: integer;
begin
  PrevPoint := Point(-1, -1);
  Canvas.Brush.Color := clWhite;
  Canvas.FillRect(ClientRect);
  for x := 0 to ClientWidth - 1 do
  begin
    logx := ScreenToLog(Point(x, 0)).X;
    logy := logx*logx; // y = f(x)
    y := LogToScreen(RealVector(logx, logy)).Y;
    CurrPoint := Point(x, y);
    if PrevPoint.X = -1 then
      Canvas.MoveTo(CurrPoint.X, CurrPoint.Y)
    else
      Canvas.LineTo(CurrPoint.X, CurrPoint.Y);
    PrevPoint := CurrPoint;
  end;
end;

不要忘记：

procedure TForm5.FormResize(Sender: TObject);
begin
  Invalidate;
end;

_{（来源：rejbrand.se）}